"You said "I myself would probably try to work with the matrix representations", but I really can't see what's the matrix used by you here."

I didn't use a matrix representation. It's what I would use if this were my problem to tackle.

"Furthermore, I want to do this in a symbolic way instead of using the matrix base, that is, the faithful representation of isomorphic matrices."

What I showed is a symbolic representation.

I myself would probably try to work with the matrix representations, and maybe use lookup to associate products with group elements. Since you seem to want to se a representation in terms of products, and bearing in mind that these do not necessarily commute, we can do as follows. I work with the example shown (where products do in fact commute).

First define the generators and the relations they satisfy.

gens = {e, p, q, r};
rels = {e ** any_ :> any, any_ ** e :> any, any_ ** any_ :> e, 
   any_ ** p :> p ** any, r ** q -> q ** r};

Next compute products of all pairs.

firstset = 
 Union[Flatten[Outer[NonCommutativeMultiply, gens, gens] /. rels]]

(* Out[12]= {e, p, q, r, p ** q, p ** r, q ** r} *)

Repeat this in order to determine whether we have all possible group elements. Notice this time I use ReplaceAllRepeated since there might need to be more than one pass using the relation rules as replacements.

nextset = 
 Union[Flatten[
   Outer[NonCommutativeMultiply, firstset, firstset] //. rels]]

(* Out[16]= {e, p, q, r, p ** q, p ** r, q ** r, p ** q ** r} *)

Maximum length is 3 (rather than 4). I think that means we have all possible group elements. We can rename them along the lines indicated in the question.

elementnames = Array[c, Length[nextset]];
morerels = Reverse[Thread[nextset -> elementnames]]

(* Out[31]= {p ** q ** r -> c[8], q ** r -> c[7], p ** r -> c[6], 
 p ** q -> c[5], r -> c[4], q -> c[3], p -> c[2], e -> c[1]} *)

We now find all products of these, and use their new names to get the requested product table. Among other things, this will show that we get no new elements from products. Note that I sorted the renamings by length in order to make sure the longest available match is tried first.

multTable = Outer[NonCommutativeMultiply, nextset, nextset] //. rels /. morerels

(* Out[29]= {{c[1], c[2], c[3], c[4], c[5], c[6], c[7], c[8]}, {c[2], c[1], c[5], c[6], c[3], c[4], c[8], c[7]}, {c[3], c[5], c[1], c[7], c[2], c[8], c[4], c[6]}, {c[4], c[6], c[7], c[1], c[8], c[2], c[3], c[5]}, {c[5], c[3], c[2], c[8], c[1], c[7], c[6], c[4]}, {c[6], c[4], c[8], c[2], c[7], c[1], c[5], c[3]}, {c[7], c[8], c[4], c[3], c[6], c[5], c[1], c[2]}, {c[8], c[7], c[6], c[5], c[4], c[3], c[2], c[1]}} *)

So this is the product table. I think something like this might work in general, though perhaps there might need to be refinements for more complicated examples.

On a different note, I have received so many edit notifications today that I had to stop following the thread. The responses seem fine, but I've yet to figure out what in the original post has changed during these six or so edits.

Then, let me ask the opposite question: How to identify/find the permissible lattice basis vectors using the space group elements?

Dear @Robert Nachbar,

Thank you very much for your wonderful code snippet. For the question I raised here, I still have the following puzzle:

Your table is based on vector multiplication, but my problem is based on abstract groups. More specifically, you have a vector/matrix based representation of the group's generators/elements/structure relationships, but for abstract groups, the only thing we know is the abstract multiplication relationship between their elements, as listed in BC book. What I want to do is exactly to construct the multiplication table based on these given abstract multiplication relationship among the group elements. This should be done based on the well-known theorems and axioms of group theory and a robust and mature symbolic algebraic system such as Mathematica, without relying on any specific representation, such as matrices.

BTW, here you can find the latest version, i.e., the sixth edition published in 2016 of "International Tables for Crystallography Volume A: Space-group symmetry".

I am not familiar with that book, however, International Tables for Crystallography, Volume A, Space Group Symmetry (online here) has the generators for each of the 230 space groups, and the 17 plane groups and the 2 line groups.

I have used them often to generate all the elements of one of the space groups, and generating the group multiplication table should be a simple matter after that.

It sounds like BC might be a good addition to my library.