There are so many details that you really need to just play with it. I have to look at the documentation for the special cases every time. Try different things and see what effect they have. But to get you started, I used this form: {spec-x, spec-y, rules}.

• spec-x controls the horizontal alignments, and it applies column-wise (more on that in a bit).
• spec-y controls the vertical alignments, and it applies row-wise.
• rules allows you to specify overrides.

Now, for spec-x and spec-y, you can specify some initial settings, repeating settings in the middle, and some terminal settings. So, for example, {Left, {"."}} means "start with Left aligned, then repeat "." aligned thereafter (with no special terminal settings). This can get quite detailed.

For rules, you can specify single cells by their coordinates (row, col, same as Part uses), or you can specify ranges/blocks (row-range, col-range).

Examine (and experiment with) this example:

Grid[
 ArrayReshape[Alphabet[], {5, 5}],
 Dividers -> All,
 ItemSize -> {5, 5},
 Alignment ->
  {{Center, {Left, Right}, Center},
   {Center, {Top, Bottom}, Center}, 
   {{1, 1} -> {Left, Top}, {{4, 5}, {3, 4}} -> {Center, Bottom}}}]

Try something like this (random data for easy display):

Grid[
 {
  {"heading", Splice[RandomWord[10]]},
  {"row1", Splice[RandomReal[{-20, 20}, 10]]},
  {"row2", Splice[RandomReal[{-20, 20}, 10]]},
  {"row3", Splice[RandomReal[{-5, 5}, 10]]}},
 Dividers -> All,
 Alignment -> {{Left, {"."}}, {Center}, {{{1, 2}, {2, 11}} -> Center}}]

Edit

Sorry, I think I misunderstood. I think this is more like it.

Grid[
 {
  {"heading", Splice[RandomWord[10]]},
  {"row1", Splice[RandomReal[{-20, 20}, 10]]},
  {"row2", Splice[RandomReal[{-20, 20}, 10]]},
  {"row3", Splice[RandomReal[{-5, 5}, 10]]}},
 Dividers -> All,
 Alignment -> {{Left, {"."}}, {Baseline}, 
   {{{1, 1}, {2, 11}} -> {Center, Baseline}}}]