Hello Werner

Hope you like this one:

In[25]:= MatchQ[{1, 20, 300}, {Repeated[Except[_List], 3]}]    
Out[25]= True

In[24]:= MatchQ[{1, {20}, 300}, {Repeated[Except[_List], 3]}]    
Out[24]= False

This follows exactly the Mathematica documentation of VectorQ

VectorQ[expr] gives True if expr is a list or a one-dimensional SparseArray object, none of whose elements are themselves lists, and gives False otherwise.

Last but not least:

MatchQ[{1, 20, 300}, _?(v \[Function] VectorQ@v && Length@v == 3)]

Robert, this solution with NumericQ works indeed. I had in mind that NumericQ was Listable, but it isn't.

MatchQ[{1, {20, 21}, 300}, {Repeated[_?NumericQ, 3]}]
(* False *)

But your original proposal does not really work since AtomQ accepts less expressions than VectorQ:

(* This works *)
b =.; vec = {1, b, 300};
{MatchQ[vec, {Repeated[_?AtomQ, 3]}], 
 MatchQ[vec, v : _ /; (VectorQ[v] && Length[v] == 3)]}
(* {True, True} *)

(* This doesn't work  *)
b = Sqrt[2]; vec = {1, b, 300};
{MatchQ[vec, {Repeated[_?AtomQ, 3]}], 
 MatchQ[vec, v : _ /; (VectorQ[v] && Length[v] == 3)]}
(* {False, True} *)

(* But at least for NumericQ, it works  *)
b = Sqrt[2]; vec = {1, b, 300};
{MatchQ[vec, {Repeated[_?NumericQ, 3]}], 
 MatchQ[vec, v : _ /; (VectorQ[v, NumericQ] && Length[v] == 3)]}
(* {True, True} *)

Yes Robert, this tests like VectorQ. But extending it to NumericQ would probably not be very readable.

I don't know what you're looking for in terms of "simpler", but I think it makes the subsequent code simpler if you wrap the conditions up in a well-named function. Parameterizing it also makes it "simpler" to extend later. Here's one way you could do that.

VectorTest[length_, test_][expr_] := 
 And[length == Length@expr, VectorQ[expr, test]]

Then your argument could be specified like this:

v_?(VectorTest[3, NumericQ])

(VectorTest is a pretty generic name, but you can probably come up with something better in your context.)