I'm surprised and grateful that you are so attentive to questions like mine from the community! Your previous coding has been monumental to me in advancing to my latest Manipulate, even if it is not apparent.

However, the slider in your manipulate reveals no hyperbola.

Where I'm really confused is with your definitions for aa and bb. These terms, hence their values, are not used in the manipulate program. Also, in manipulate you have an undefined a2. Shouldn't a2 have a value or range of values in manipulate?

I did replace a2 with your definitions in all the ways I could think of, and I did get the slider to trace out a left branch of an approximate hyperbola from bottom to top. What I want, however is for the slider to reveal the red hyperbola so that what is shown is always parallel to the transverse axis. I hope the two screenshots shown below for two different slider positions will show what I mean.

Is it possible to reveal the red hyperbola as the slider moves the tilted (imaginary) red line back and forth along the main axis?

If my remarks seem like criticism, please know that that any code you write personalized for me is the best learning experience I have going. I think my failing to precisely communicate what I want while trying to do it in as few words as possible is a standard in this community that I'm just starting to learn. If I'm not getting what I want, it's a fault I'll have to overcome. I benefit from all your code. To have attracted your interest is almost beyond belief.

For what it's worth, I think this is what I wanted to provide before:

aa = Sqrt[13/3];
bb = Sqrt[13/3];
hyperbolaX[a_][t_] := a Sec[t];
hyperbolaY[b_][t_] := b Tan[t];Manipulate[
 Show[{ContourPlot[{-10 x - x^2 + (2 y)/Sqrt[3] + 2 Sqrt[3] x y + 
       y^2 == 0, y == 2/Sqrt[3] - x/Sqrt[3], 
     y == Sqrt[3] x + 8/Sqrt[3]}, {x, -14, 9}, {y, -6, 10}, 
    ContourStyle -> {{Directive[Black, Dotted]}, {Directive[Black, 
        Dotted]}}], 
   ParametricPlot[(TranslationTransform[{-3/2, 7/(2 Sqrt[3])}]@*
       RotationTransform[-Pi/6])[{hyperbolaX[aa][t], 
      hyperbolaY[bb][t]}], {t, Pi/2 + .1, s}, 
    PlotStyle -> {Red, Thickness[.02]}]}, 
  AspectRatio -> Automatic], {{s, Pi}, Pi/2 + .2, 3 Pi/2 - .1}]

OMG that is unbelievable! Your modifications provide exactly what I was looking for! Even more amazing is that you pretty much left my basic program as it was and inserted a single function you defined to accomplish the feat.

I'm glad you used pure functions. I'm sorry to say that even though I've been using Mathematica off and on for nearly 20 years, I still don't understand pure functions, and have no idea when they should be the function of choice. I know you used them because they were especially advantageous in some way. But I have no idea of the advantage you gained; all I see is confusion.

I've never learned any kind of programming except what I've learned about Mathematica through self-study. And I'm not a dedicated programmer. Rather I've tried to use Mathematica as a research and study aid, so there have been stretches of years when I've drifted away from using it.

Nevertheless, I've done countless practice examples with pure functions, but never have been able to see the light. It's always seemed as if they were like foreign words for which there was no dictionary.

Therefore, what makes your pure functions so significant is that they are cast in a programming framework I've been struggling with for quite a while. Hopefully that will make them understandable to me. Finally, I apologize for taking up your time writing so much and saying nothing to your benefit. However, if you are still with me, would you consider writing for me the code the cumbersome way I would?

I really did not think anyone would be interested in answering my question. But thanks to you, I now have exactly what I was not sure I would ever get!

William Stockich

Your hyperbola does not depend on p, so that it is better to pre-calculate it before feeding it to Manipulate. I have rearranged things a little in a way that seems a little cleaner to me:

hyperbola = 
  ContourPlot[{-10 x - x^2 + (2 y)/Sqrt[3] + 2 Sqrt[3] x y + y^2 == 0,
     y == 2/Sqrt[3] - x/Sqrt[3], y == Sqrt[3] x + 8/Sqrt[3]},
   {x, -9, 7}, {y, -6, 10},
   ContourStyle -> Directive[Black, Dotted], ImageSize -> 20.1 16.1];
sliderHyperbola[p_] := 
  ContourPlot[-10 x - x^2 + (2 y)/Sqrt[3] + 2 Sqrt[3] x y + y^2 == 
    0, {x, -14, 9}, {y, -6, 10}, ContourStyle -> Red, 
   RegionFunction -> Function[{x, y}, y > x Sqrt[3] - p]];
Manipulate[
 Show[hyperbola, sliderHyperbola[p]],
 {p, -14, 8}]

I hope it doesn't confuse you.

That post was mine (this is Eric). Sometimes this site sets the name to "Updating Name" for some reason. Must be some sort of error condition that triggers that.

Anyway, I would try to show you another way to write MyRegionFunction, but it's being used in the RegionFunction option, and that option seems to expect a Function expression, so there's no point in trying to show you a different way to do it.

Now, if your confusion is just with the # and & stuff, then another user (who's name I don't know because for me it's just showing as "Updating Name") wrote it this way: RegionFunction -> Function[{x, y}, y > x Sqrt[3] - p]]

If that's what you're asking for, then there you have it with thanks to that mystery, anonymous user.

I get the output as expected, no errors, in both versions 12.0 and 13.2. What version are you using? Try with a fresh kernel.

I wonder why you set ImageSize -> 20.1 16.1, which seems bizarre to me. Did you mean to give separate width and height? That is done with ImageSize -> {20.1, 16.1}.

Don't worry about the name.

ImageSize specifies the size in printer points. Your 16 by 16 is very very small. The picture becomes visible because you wrote 20.1 16.1, which is interpreted as a multiplication.

I have no idea why you cannot reproduce the Manipulate.

You might try RegionFunction. Let's create a function to use:

MyRegionFunction[p_] := #2 > #1 Sqrt[3] - p &

Here's an updated version of your Manipulate. I removed some options and removed a stray ImageSize option, so you might need to put some things back in. The important change is with how sliderHyperbola is defined. There might be a more performant way to do this, but this at least gets you the functionality you want (I think :) ).

Manipulate[
 Module[
  {hyperbola, sliderHyperbola},
  hyperbola =
   ContourPlot[
    {-10 x - x^2 + (2 y)/Sqrt[3] + 2 Sqrt[3] x y + y^2 == 0,
     y == 2/Sqrt[3] - x/Sqrt[3],
     y == Sqrt[3] x + 8/Sqrt[3]},
    {x, -14, 9}, {y, -6, 10}, 
    ContourStyle -> {{Directive[Black, Dotted]}, {Directive[Black, 
        Dotted]}}];
  sliderHyperbola =
   ContourPlot[
    -10 x - x^2 + (2 y)/Sqrt[3] + 2 Sqrt[3] x y + y^2 == 0,
    {x, -14, 9}, {y, -6, 10},
    ContourStyle -> Directive[Red],
    RegionFunction -> MyRegionFunction[p]];
  Show[
   hyperbola,
   sliderHyperbola,
   Frame -> True,
   ImageSize -> 20.1 16.1,
   AspectRatio -> Automatic, PlotRange -> {{-9, 7}, {-6, 10}}]],
 {p, -14, 8}]

I actually didn't post anything new recently. I don't know why it says I did. But anyway, it's easy to add a line. Starting with Gianluca's version, just add a graphics element with an InfiniteLine:

hyperbola = 
  ContourPlot[{-10 x - x^2 + (2 y)/Sqrt[3] + 2 Sqrt[3] x y + y^2 == 0,
     y == 2/Sqrt[3] - x/Sqrt[3], y == Sqrt[3] x + 8/Sqrt[3]}, {x, -9, 
    7}, {y, -6, 10}, ContourStyle -> Directive[Black, Dotted], 
   ImageSize -> 20.1 16.1];
sliderHyperbola[p_] := 
  ContourPlot[-10 x - x^2 + (2 y)/Sqrt[3] + 2 Sqrt[3] x y + y^2 == 
    0, {x, -14, 9}, {y, -6, 10}, ContourStyle -> Red, 
   RegionFunction -> Function[{x, y}, y > x Sqrt[3] - p]];
Manipulate[
 Show[hyperbola, sliderHyperbola[p], 
  Graphics[{Blue, InfiniteLine[{0, -p}, {1, Sqrt[3]}]}]], {p, -14, 8}]

Just style it however you want.

Hmm. That's weird. Maybe different version behave differently. I'm using 13.2. Anyway, glad you got something working!