Since you're new to Mathematica, I'm going to be presumptuous and provide some guidance that you didn't ask for about something that commonly trips up newcomers.

Understand that NumberForm is just a special wrapper. Evaluate this:

NumberForm[1`20, 20]

The result will look something like this: 1.0000000000000000000. But if you look at the actual structure of the result by evaluating FullForm,

FullForm[NumberForm[1`20, 20]]

you'll see that it's

NumberForm[1.`20., 20]

NumberForm, and all of the related *Form functions are just wrappers that tell the front end how to display something. This can cause problems if you subsequently want to do calculations:

NumberForm[1`20, 20] + 1

The result displays as 1+1.0000000000000000000, because the evaluator doesn't know how to do arithmetic with NumberForm expressions, and the evaluator is looking at

Plus[1, NumberForm[1.`20., 20]]

Glad to have you jump in. I gather that all of the display commands should be the last things(outermost in syntax) executed, since I assume they do just that - only affect the display, and can't calculate as you point out.

A preamble about asking for help. I looked first in the documentation for aid in all the things I am asking here. Finding things is not straightforward if you don't know how to phrase the question. Somewhat frustrating. I have made progress, and now have some new questions as a result. I,m not sure whether or not to start a new topic, so I'll just start here and ask all the new questions. Please recommend which - if any - should be posted as new threads.

Issue 1: The numbering in the workbook is not sequential now. I had not been paying attention, but does re-evaluating an input screw up the numbering?

Issue 2: I have managed to create two columns (more seem straightforward) of displayed numbers - essentially an x-vector and a y-vector, where each y is a function of the corresponding x (I use "vector" loosely, in the sense I am used to, not necessarily the Mathematica syntax). In this case, the function is EllipticK. See in-out(142) in attached. I would like to export these numerical values to a csv file. What I want the output to look like is in the file "desired.csv" attached. I tried doing an export to csv. What I got is in the file "wmdata2.csv." See in-out(137). Clearly, M (Mathematica) doesn't treat my two-column display as a single array. I don't know how to do that, nor whether that will help create the desired output file.

Issue 3: I could not set the current working directory. See in -out(134,135, 136). The directory "D:\temp" is valid. I thought my SetDirectory syntax was correct. It didn't work. What am I missing in the syntax? what is wrong with In(135)?

Issue 4: I am counting on M to be the gold standard with arbitrary precision. Some calc examples leave me puzzled. See I-O(152,146,150) - three sequential evals with EllipticK. The input arguments in (152) and (15) are exactly the same; one is a fraction, the other a decimal. However, the output values differ after the tenth decimal place. I really need to understand what is going on here, and why the returned value is not to the requested precision. No error message/qualifier is visible.

Thx, Lou

Attachments:

Wnotebook2.pdf

desired2.csv

wmdata2.csv

Issue 3: I could not set the current working directory. See in -out(134,135, 136). The directory "D:\temp" is valid. I thought my SetDirectory syntax was correct. It didn't work. What am I missing in the syntax? what is wrong with In(135)?

Looks to me like you need to escape the \. If you look at the message, it looks like the \t was interpreted as a tab. You probably need something like "D:\temp". You can also use FileNameJoin to avoid dealing with system-dependent delimiters.

Issue 2: I have managed to create two columns (more seem straightforward) of displayed numbers... I would like to export these numerical values to a csv file...

The problem here is that Column. That's another display wrapper, and you don't want it to be exported. In general, as you're doing your computations, keep the data in its "native" form and only use the display forms for dispaly--don't let them leak into the actual data. So, let's try again:

x = {1, 2, 4, 6, 7, 49.999999}; (* Good! Simple data. *)
xn = N[x/50, 20]; (* Still just simple data. Note the precision of the last value won't have changed, however. *)
Column[xn] (* Now you can look at what you have. TableForm is probably the better choice for display, however. *)

yn = Map[EllipticK, xn]; (* This will be a list of the results. We can't do much about the precision of the output, 
since we've already set the precision of our inputs. Refer to my other post to address that aspect. *)

Transpose[{xn, yn}] // TableForm (* Looking at what we have now. The Transpose gets them paired properly. 
We don't really need to store this in a variable just to look at it, but we could have done that if we wanted.*)

Export[FileNameJoin[{$HomeDirectory, "test.csv"}], Transpose[{xn, yn}]]
(* This should get you a well-formated csv in your home directory. You could change the format of the numbers before you export if you wanted to. *)

Please use one of the methods explained here http://wolfr.am/READ-1ST to include your formatted code or notebook. Thank you.

So, just don't do this:

xn = N[Column[x/50], 20]

There's no reason to set a variable to a Column expression. I mean, I suppose there could be a case where you're building up a visual display and so you want to have a variable to represent part of that display so you can refer to it, but to me it looks like you're trying to compute some data, and in that case the Column is just going to make life difficult.

If you like looking at your data at certain points during the calculation, then do this:

xn = N[x/50, 20];
Column[xn]

Your variable xn will be set to something useful, and you'll have a nice display of it to look at.

It might be better at this point to add a new question. By starting fresh you can isolate your new question, and then maybe folks can understand better what you're asking.