A side observation...

If one computes

theIntegral = Integrate[1/Sqrt[2 (1 + x)^3 + 1], x]

and then computes

theDerivative = D[theIntegral, x] // FullSimplify

which yields

-(((-1)^(5/6) Sqrt[3] Sqrt[
     1 + 2 (1 + x)^3])/(Sqrt[-(-1)^(5/6) (1 + 2^(1/3) + 2^(1/3) x)]
      Sqrt[(-1)^(5/6) (-1 + (-2)^(1/3) (1 + x))] Sqrt[
     1 + (-2)^(1/3) (1 + x) + (-2)^(2/3) (1 + x)^2] Sqrt[
     3 - (-1)^(1/6) Sqrt[3] + (1 + x) Root[108 + #1^6 &, 1]] Sqrt[
     3 + (-1)^(5/6) Sqrt[3] + (1 + x) Root[108 + #1^6 &, 2]])) 

and then attempts to Plot this using

Plot[-(((-1)^(5/6) Sqrt[3] Sqrt[
      1 + 2 (1 + x)^3])/(Sqrt[-(-1)^(5/6) (1 + 2^(1/3) + 2^(1/3) x)]
       Sqrt[(-1)^(5/6) (-1 + (-2)^(1/3) (1 + x))] Sqrt[
      1 + (-2)^(1/3) (1 + x) + (-2)^(2/3) (1 + x)^2] Sqrt[
      3 - (-1)^(1/6) Sqrt[3] + (1 + x) Root[108 + #1^6 &, 1]] Sqrt[
      3 + (-1)^(5/6) Sqrt[3] + (1 + x) Root[108 + #1^6 &, 2]])) , {x, 0, 1}]

the result is that it crashes the Mathematica Kernel. (I will report this.)

In[1]:= SystemInformation["Small"]

Out[1]= {"Kernel" -> {"SystemID" -> "MacOSX-x86-64", 
   "ReleaseID" -> "10.0.0.0 (5098698, 5098537)", 
   "CreationDate" -> 
    DateObject[{2014, 6, 29}, TimeObject[{20, 38, 32}]]}, 
 "FrontEnd" -> {"OperatingSystem" -> "MacOSX", 
   "ReleaseID" -> "10.0.0.0 (5098698, 2014062704)", 
   "CreationDate" -> 
    DateObject[{2014, 6, 27}, TimeObject[{23, 17, 40.}]]}}

There is a path singularity around .59 that is not found. Will investigate.

I see what you mean

sln = DSolve[{y'[x] == 1/Sqrt[2 (1 + x)^3 + 1], y[0] == 0}, y]

Plot [Im[y[x] /. sln], {x, 0, 1}, PlotRange -> All ] shows that y[x] develops an imaginary part at 0.59

@otsocol, Yes, I was looking at that antiderivative.

As to whether the antiderivative itself is correct, About all I can say is it gives a numerical result consistent with NIntegrate if one only integrates from 0 to 1/2 (which excludes that singularity point). This might or might not answer your question.

Plotting theDerivative using

Plot[theDerivative,{x,0,1}] 

does not crash my Kernel, but plotting the full expression for theDerivative as written in my post does crash it reproducibly.

I filed a bug report.

Regarding the crash associated with plotting a long expression, I wonder if the bug is related to this post: http://community.wolfram.com/groups/-/m/t/314527?p_p_auth=3uJCatzr

Postscript: I tried the plot in http://community.wolfram.com/groups/-/m/t/314527?p_p_auth=3uJCatzr, but using a shorter expression for the first argument to Plot. The plot in that post still crashes (randomly, it seems). So, perhaps the bugs are not relatives.

Slipping in Evaluate prevents the crash. fyi.

Plot[ Evaluate[-(((-1)^(5/6) Sqrt[3] Sqrt[
        1 + 2 (1 + x)^3])/(Sqrt[-(-1)^(5/6) (1 + 2^(1/3) + 
           2^(1/3) x)] Sqrt[(-1)^(5/
            6) (-1 + (-2)^(1/3) (1 + x))] Sqrt[
        1 + (-2)^(1/3) (1 + x) + (-2)^(2/3) (1 + x)^2] Sqrt[
        3 - (-1)^(1/6) Sqrt[3] + (1 + x) Root[108 + #1^6 &, 1]] Sqrt[
        3 + (-1)^(5/6) Sqrt[3] + (1 + x) Root[108 + #1^6 &, 
           2]]))], {x, 0, 1}]

Ditto pre-processing the expression with FullSimplify.

expr2 = FullSimplify[  expr , x >= 0] 

I don't want to discourage your reporting the crash.

Much simpler example that causes the crash:

Plot[Root[108 + #1^6 &, 2], {x, 0, 1}]

One gets the intended result with a simple shift of the integration variable of the definite integral

In[87]:= NIntegrate[1/Sqrt[2 (1 + x)^3 + 1], {x, 0, 1}]
Out[87]= 0.376065

In[88]:= $Version
Out[88]= "10.0 for Microsoft Windows (64-bit) (June 29, 2014)"

Let y = x + 1, dy = dx and

In[90]:= NIntegrate[1/Sqrt[2 y^3 + 1], {y, 1, 2}]
Out[90]= 0.376065

In[91]:= Integrate[1/Sqrt[2 y^3 + 1], {y, 1, 2}]
Out[91]= Sqrt[2]*Hypergeometric2F1[1/6, 1/2, 7/6, -1/2] - Hypergeometric2F1[1/6, 1/2, 7/6, -1/16]

In[92]:= % // N
Out[92]= 0.376065

With other words, from 1 to 2 one does not encounter a singularity like the one Daniel mentioned, because

In[117]:= (Integrate[1/Sqrt[2 y^3 + 1], y] /. y -> x + 1) ===  Integrate[1/Sqrt[2 (1 + x)^3 + 1], x]
Out[117]= True

of course.

Yes, for the indefinite integral you're right; it is still in Version 10.0.0 the case. The difference of valued indefinite integrals does not convert into the Hypergeometric2F1[] form and the bug reappears

In[11]:= N[(ReplaceAll[#, y -> 2] - ReplaceAll[#, y -> 1]) &[Integrate[1/Sqrt[2 y^3 + 1], y]]]
Out[11]= -2.96267 - 1.92762 I

In[15]:= N[FullSimplify[(ReplaceAll[#, y -> 2] - ReplaceAll[#, y -> 1])] &[Integrate[1/Sqrt[2 y^3 + 1], y]]]
Out[15]= -2.96267 - 1.92762 I

In[17]:= (Integrate[1/Sqrt[2 y^3 + 1], y] /. y -> x + 1) === Integrate[1/Sqrt[2 (1 + x)^3 + 1], x]
Out[17]= True

that means this is a bug not about a path singularity, because the indefinite integral does not go along a path. It's something about turning back to the right leaf. For example, look at this, the derivative does not turn back to the original integrand, but presents an equation of six-th degree instead:

Let me add two remarks

1) the exact value of the jump position seems to be xj = 2^(2/3) - 1

N[2^(2/3) - 1, 20]
(* 0.58740105196819947475 *)

2) an antiderivative without a jump can be calculated as follows

ad2F1[x_] = Integrate[1/Sqrt[1 + 2 x^3], {x, 0, t}, Assumptions -> t > 0] /. t -> 1 + x

(* Out[116]= (1 + x) Hypergeometric2F1[1/3, 1/2, 4/3, -2 (1 + x)^3] *)

Hence we find a hypergeometric function instead of the "bizarre" elliptic integral.

Proof

D[ad2F1[x], x] // Simplify

(* Out[109]= 1/Sqrt[1 + 2 (1 + x)^3] *)