With change variable we have:
$\int_{-\phi }^{\phi } \frac{\sqrt{1+e^{2 i \theta }-2 e^{i \theta } \cos (\phi )}}{1+e^{i \theta } \alpha } \, d\theta =\int_{\cos (\phi )-i \sin (\phi )}^{\cos (\phi )+i \sin (\phi )} -\frac{i
\sqrt{1+x^2-2 x \cos (\phi )}}{x+x^2 \alpha } \, dx$
HoldForm[
Integrate[Sqrt[
1 + E^(2 I \[Theta]) - 2 E^(I \[Theta]) Cos[\[Phi]]]/(
1 + E^(I \[Theta]) \[Alpha]), {\[Theta], -\[Phi], \[Phi]}] ==
Integrate[-((I Sqrt[1 + x^2 - 2 x Cos[\[Phi]]])/(
x + x^2 \[Alpha])), {x, Cos[\[Phi]] - I Sin[\[Phi]],
Cos[\[Phi]] + I Sin[\[Phi]]}]] // TeXForm
then:
IntegrateChangeVariables[
Inactive[Integrate][-((I Sqrt[1 + x^2 - 2 x Cos[\[Phi]]])/(
x + x^2 \[Alpha])), {x, Cos[\[Phi]] - I Sin[\[Phi]],
Cos[\[Phi]] + I Sin[\[Phi]]}], t, t == x - Exp[I*\[Phi]],
Assumptions -> 0 < \[Alpha] < 1 && 0 < \[Phi] < Pi]
(* Can't compute. Weakness!!! *)
IntegrateChangeVariables[
Inactive[Integrate][-((I Sqrt[1 + x^2 - 2 x Cos[\[Phi]]])/(
x + x^2 \[Alpha])), x], t, t == x - Exp[I*\[Phi]],
Assumptions ->
0 < \[Alpha] < 1 && 0 < \[Phi] < Pi] // FullSimplify(*OK*)
(*Then:*)
W = Integrate[-((
I Sqrt[t (t + 2 I Sin[\[Phi]])])/((E^(I \[Phi]) +
t) (1 + (E^(I \[Phi]) + t) \[Alpha]))), t]
(* -((2 I E^(-I \[Phi]) Sqrt[
t] (-((E^(I \[Phi]) + \[Alpha]) Sqrt[1 + E^(I \[Phi]) \[Alpha]]
ArcTan[(Sqrt[t] Sqrt[-1 - E^(-I \[Phi]) \[Alpha]])/(
Sqrt[1 + E^(I \[Phi]) \[Alpha]] Sqrt[t + 2 I Sin[\[Phi]]])]) +
E^(I \[Phi]) \[Alpha] Sqrt[-1 - E^(-I \[Phi]) \[Alpha]]
ArcTanh[(E^(-I \[Phi]) Sqrt[t])/Sqrt[t + 2 I Sin[\[Phi]]]] +
E^(I \[Phi]) Sqrt[-1 - E^(-I \[Phi]) \[Alpha]]
Log[Sqrt[t] + Sqrt[t + 2 I Sin[\[Phi]]]]) Sqrt[
t + 2 I Sin[\[Phi]]])/(\[Alpha] Sqrt[-1 - E^(-I \[Phi]) \[Alpha]]
Sqrt[t (t + 2 I Sin[\[Phi]])]))*)
FullSimplify[(Limit[W,
t -> (x - Exp[I*\[Phi]] /. x -> Cos[\[Phi]] + I Sin[\[Phi]] //
ComplexExpand),
Assumptions -> 0 < \[Alpha] < 1 && 0 < \[Phi] < Pi,
Direction -> -1] -
Limit[W,
t -> (x - Exp[I*\[Phi]] /. x -> Cos[\[Phi]] - I Sin[\[Phi]] //
ComplexExpand),
Assumptions -> 0 < \[Alpha] < 1 && 0 < \[Phi] < Pi,
Direction -> -1]) // PowerExpand,
Assumptions -> 0 < \[Alpha] < 1 && 0 < \[Phi] < Pi] // Expand
(* \[Pi] + \[Pi]/\[Alpha] - (\[Pi] Sqrt[
1 + \[Alpha]^2 + 2 \[Alpha] Cos[\[Phi]]])/\[Alpha]*)
$\int_{-\phi }^{\phi } \frac{\sqrt{1+e^{2 i \theta }-2 e^{i \theta } \cos (\phi )}}{1+e^{i \theta } \alpha } \, d\theta =\pi +\frac{\pi }{\alpha }-\frac{\pi \sqrt{1+\alpha ^2+2 \alpha \cos (\phi )}}{\alpha
}$
Regards M.I.
