If you replace Legendre
$P_n$ by its asymptotic expansion, convert the cosines into terms of
$e^{in\theta}$, and split the series into a series of each term, it gets the desired result:
pn = Series[ (* get asymptotic expansion of LegendreP[] *)
LegendreP[n, Cos[\[Theta]]],
{n, Infinity, 0},
Assumptions -> (0 < \[Theta] < \[Pi] && n \[Element] Integers &&
n > 0)];
Assuming[0 < \[Theta] < \[Pi] && n \[Element] Integers && n > 0,
Normal[pn] // Simplify //
ReplaceAll[Sin[\[Theta]] -> s] // (* get around TrigToExp *)
TrigToExp //(* SumConvergence knows more about Exp[I n \[Theta]] *)
Expand // (* expand into sum of terms *)
Apply@List // (* split terms *)
ReplaceAll[s -> Sin[\[Theta]]] // (* put back Sin[] *)
(*Echo//*) (* place Echo[] to show any intermediate result *)
SumConvergence[(* test convergence of series of each term *)
t^n #, n,
Assumptions -> (0 < \[Theta] < \[Pi] && 0 < s <= 1 &&
n \[Element] Integers && n > 0)] & //
Apply@And // (* require all series to converge *)
Simplify] (* simplify And[...] *)
(* t == -1 || t == 1 || Abs[t] < 1 *)
