Hi Gianluca,
I don't know. My impression is that the documentation has never been complete. From time to time, WRI makes an effort to build out the documentation to include missing descriptions and new behavior, but they never seem to fill in all the missing details. Perhaps initially they are tentative about the behavior of an option value, and a version or two later, when the behavior is finalized, somehow the documentation is not updated.
I usually assume there's some meaning to option settings like None/All, True/False, and Automatic, when the setting makes sense for the option. Perhaps people should submit requests to have it documented, so that it ends up on a developer's to-do list. Especially when you consider the following timings and output sizes:
poly = 2 x^9 - 10 x^6 + 10 x^3 - 2;
Factor[poly, Extension -> ComplexExpand@SolveValues[poly == 0, x]] //
LeafCount // AbsoluteTiming
(* {30.4158, 2239} <-- slowest, large *)
Factor[poly, Extension -> Last /@ List @@ Roots[poly == 0, x]] //
LeafCount // AbsoluteTiming
(* {12.948, 36343} <-- slow, largest *)
(p1 = Factor[poly, Extension -> All]; p1) //
LeafCount // AbsoluteTiming
(* {0.002003, 123} <-- fast, smallest, simplest code *)
(p2 = Last@CoefficientList[poly, x] (Times @@
Subtract @@@ List @@ Roots[poly == 0, x]); p2) //
LeafCount // AbsoluteTiming
(* {0.001257, 123} <-- fastest, smallest, but complicated code *)
p1 === p2
(* True <-- last two factorizations are identical *)
The first example above is your method; the second is a modification of your method (I didn't expect to be so much different, though); the third is mine; and the fourth constructs the factors by hand and is my guess at what Factor[..., Extension -> All] probably does, although I expected the two to be closer in timings.
