You could use Ratios to get the 3:1-type analysis or normalize the eigenvectors to have one of its components to be 1:

evecs = Eigenvectors[N@{{-3, 2}, {-15, 9}}];
Ratios /@ evecs
Normalize[#, Min[Abs[Select[#, # != 0 &]]] &] & /@ evecs
Normalize[#, Norm[#, Infinity] &] & /@ evecs
#/First[#] & /@ evecs
(*
{{-0.230336, -0.973111}, {-0.49079, -0.871278}}  <-- e-vectors
{{4.22474}, {1.77526}}                           <-- ratios of components
{{-1., -4.22474}, {-1., -1.77526}}               <-- smallest component ±1
{{-0.236701, -1.}, {-0.563299, -1.}}             <-- largest component ±1
{{1., 4.22474}, {1., 1.77526}}                   <-- first component 1 (beware ÷0)
*)

Happy holidays to you, too!

Thanks for the information. I am still trying to understand exactly what the unit circle with vectors pointing outward is indicating. Looking at vectors in the plane, it is somewhat easy to identify and understand the flows, but the unit circle vectors is a bit of a stretch for me. In any event, thanks for the help, and have a very merry Christmas and a wonderful New Year.

Mitch Sandlin

Mitchell,

in your code you have too many curly brackets; try

Graphics[{Red, Arrow[{{0, 0}, 3 {1, 3}}], Blue, Arrow[{{0, 0}, 2 {2, 5}}]}, Axes -> True, AxesLabel -> {"x", "y"}]

For an understanding of eigenvectors here is a simple example to play with: Red are the eigenvectors, green represents the input vector and blue the resulting output. The vectors of the vector field gives the direction of this output.

mat = {{1., -.5}, {-1, -.5}};
{ev, evec} = Eigensystem[mat];
Manipulate[
 VectorPlot[mat . {x, y}, {x, -3, 3}, {y, -3, 3}, 
  Epilog -> {Red, Arrow[ev[[1]] {{0, 0}, evec[[1]]}], 
    Arrow[ev[[2]] {{0, 0}, evec[[2]]}], 
    Arrow[-ev[[1]] {{0, 0}, evec[[1]]}], 
    Arrow[-ev[[2]] {{0, 0}, evec[[2]]}], Green, Arrow[{{0, 0}, vec}], 
    Blue, Arrow[{{0, 0}, mat . vec}]}, 
  PerformanceGoal -> "Quality"], {{vec, {1, 1}}, Locator}]

Does that help? Regards -- Henrik