With my own old CurvesGraphics6 package we can easily draw stream lines onto the potential surface:

Module[{q1 = -0.5, q2 = 0.25, q3 = 0.74, potential},
 potential[x_, y_] = -(q1/EuclideanDistance[{x, y}, {1, 1}]) -
    q2/EuclideanDistance[{x, y}, {0, -1}] -
    q3/EuclideanDistance[{x, y}, {-1, 1}] /. Abs -> Identity;
 forceField[x_, y_] = D[potential[x, y], {{x, y}}];
 PlotCurveOnSurface3D[{{x, y, potential[x, y]},
   {x, -2, 2}, {y, -2, 2}},
  {forceField[x, y],
   {x, -2, 2}, {y, -2, 2},
   StreamColorFunctionScaling -> False}]]

The package is available on my site.

Is the problem limited to fields with holes?

I'd say that two independent plots are very likely to sample different points. If the norm does not change rapidly, then the color scale range of the two plots is likely to be similar, and the user is unlikely to notice the small difference in the coloring of the plot. If norm changes rapidly or through a few orders of magnitude, then the ranges of the norm at the sample points of each plot is likely to be different. This certainly happens near points where the norm goes to infinity ("holes", as you call them). Principle: Very large rate of change (derivative) times small difference in input => large difference in output.

Are such fields the motivation for StreamColorFunction?

Another use is to match a standard color scheme used in some field or other; or simply because users like their own color schemes. For instance, one might want to replicate the wind-velocity scale at the following site; also, it is absolute (equivalent to StreamColorFunctionScaling -> False) and not relative, so that colors are comparable from day to day:

https://earth.nullschool.net/#current/wind/isobaric/500hPa/orthographic

Thanks, Gianluca Gorni. That brings the color scaling into conformity but the magnitudes of the vectors are still in conflict. I'm not sure either is correct. I couldn't post two versions in the same reply. So I'll reply again with a revised verstion.

I should have been more precise. The conflict I referred to is between values as shown in the legends. The extreme range in the streamplot version of the same vector field may be what accounts for the missing color range in the streams when color scaling was not disabled.

Michael Rogers later post identified the issue. The two vector field visualization functions have different sampling densities. So on a field like this with holes, StreamPlot with finer sampling picks up extreme values.

The problem is that the range of the magnitude of the norm of the vectors is different in each plot. The sampling in the StreamPlot[] is much denser than the sampling in the VectorPlot[]. Since the norm of the vector goes to infinity near the q points, the sampling makes a big difference here. I think you need to do manual scaling of the color function, the same scaling for both plots. Something like:

StreamColorFunctionScaling -> False, 
StreamColorFunction -> Function[{x, y, vx, vy, n}, 
  ColorData["WL12DefaultVectorGradient"][
   Rescale[Clip[n, {0, 2.5*^10}], {0, 2.5*^10}]]]

This messes up the plot legends, though, and the documentation does not seem to suggest a way out. (It should, imo.) So here's a hack:

Manipulate[
 Column[
  Module[{norm, q, field, \[Epsilon]₀, format},
   norm[vec_] := Sqrt[Total[vec^2]];
   q := {{q1, {1, 1}}, {q2, {0, -1}}, {q3, {-1, 1}}}; 
   \[Epsilon]₀ = 8.85418782 10^-12;
   field = 1/(4 \[Pi] \[Epsilon]₀ ) \!\(
\*UnderoverscriptBox[\(\[Sum]\), \(i = 1\), \(3\)]
\*FractionBox[\(q[[i, 1]]\ \(({x, y} - q[[i, 2]])\)\), 
SuperscriptBox[\(norm[{x, y} - q[[i, 2]]]\), \(3\)]]\);
   format = {PlotLabel -> "Electric Field for Three Point Charges"
     , PlotLegends -> Automatic
     , Epilog -> {Red, PointSize[0.02`], 
       Table[Point[q[[i, 2]]], {i, 1, Length[q]}]}
     , ImageSize -> Medium};
   With[{vplot = 
      VectorPlot[field, {x, -2, 2}, {y, -2, 2}, 
       VectorScaling -> Automatic, Evaluate[format]]},
    {leg = Last@vplot},(* legend from vector plot *)
    {scf = leg[[1, 1, 1]], (* StreamColorFunction from vector plot *)
     normRange = leg[[1, 1, 2]]}, (* norm range from vector plot *)
    {vplot,
     StreamPlot[field
      , {x, -2, 2}, {y, -2, 2}
      , StreamColorFunctionScaling -> False
      , StreamColorFunction -> 
       Function[{x, y, vx, vy, n}, 
        scf[Rescale[Clip[n, normRange], normRange]]]
      , PlotLegends -> leg
      , Evaluate[format]]}
    ]
   ]],
 Row[
  {Control[{{q1, -0.05}, ControlType -> InputField}], Spacer[30],
   Control[{{q2, 0.025}, ControlType -> InputField}], Spacer[30],
   Control[{{q3, 0.03}, ControlType -> InputField}]}]]

I believe StreamPlot[] uses the vector field values at the beginning of a streamline arrow, where as VectorPlot[] uses the values at the middle of the vector arrow. Consequently, getting identical colors in both plots at the same points in the plane is a rather difficult battle to win. I imagine it could be done by post-processing the graphics.