If we start with few foxes and many rabbits, fow a while the rabbits will increase. It will take time before the foxes catch up and they will both go extinct. Here is an example:

mat = {{6/10, 1/2}, {-(7/40), 6/5}};
f[t_] = MatrixPower[mat, t];
ParametricPlot[f[t] . {0, 1}, {t, 0, 30},
  PlotRange -> {{0, 2.1}, {0, 2}},
  AxesLabel -> {"foxes", "rabbits"}] /. Line -> Arrow

Using discrete steps:

mat = {{6/10, 1/2}, {-(7/40), 6/5}};
f[t_] = MatrixPower[mat, t];
pts = Table[f[t] . {0, 1}, {t, 0, 30}];
Graphics[{Arrowheads[{.05, .05, .05, .05}], Arrow[pts], 
  PointSize[Medium], Point[pts]}, PlotRange -> {{0, 2.1}, {0, 2}}, 
 Axes -> True, AxesLabel -> {"foxes", "rabbits"}]

Your initial picture only shows the regime where both decrease.

Using MatrixPower:

mat = {{6/10, 1/2}, {-(7/40), 6/5}};
eigen = Eigenvectors[mat];
f[t_] = MatrixPower[mat, t];
ParametricPlot[{f[t] . {1, 1},
  f[t] . eigen[[1]], f[t] . eigen[[2]],
  f[t] . {1, 0}}, {t, 0, 20}] /. Line -> Arrow

This is probably the nicest way to see the overall behavior of the system.

Not quite sure of what you want, but if you want to see a preditor-prey population pair evolve over time, you can use ParametricPlot, yes. The whole eigenvector business is just turning the matrix arithmetic into scalar arithmetic, which means you can use a simple variable in your ParametricPlot.

Block[
 {k},
 With[
  {m = {{6/10, 1/2}, {-7/40, 6/5}}},
  {initialPopulations = {20, 50}},
  {es = Eigensystem[m]},
  {lc = SolveValues[k . es[[2]] == initialPopulations, k \[Element] Vectors[2, Reals]]},
  populationFn = Function[t, Total[es[[1]]^t lc[[1]] es[[2]]]]]]

Demonstration:

populationFn[6.5] // N
(* {80.7071, 69.0127} *)
(* about 81 foxes and about 69 rabbits *)

ParametricPlot[populationFn[t], {t, 0, 10}]

Explanation:

You don't necessarily need the Block, but I'm using the variable k in the Solve, and I just want to avoid a conflict.

The m is simply your predator-prey discrete dynamical system. initialPopulations is just an initial condition that I made up: 20 foxes and 50 rabbits. We need an initial value before we can solve for the linear combination of eigenvectors that we'll be using.

I'm using Eigensystem as a shortcut rather than calculating the eigenvectors and eigenvalues separately.

The lc is the linear combination of the eigenvectors that give the initial value.

The output is a function, and we can plug it into ParametricPlot. I'm just doing the standard arithmetic inside the Function. Note how we've moved from applying the matrix to do updates to just using scalars.

This doesn't look like the picture you posted, but I'm not sure what you were going for anyway. Ask follow ups if this doesn't help.

how you picked the time integral of 6.5

I just made it up. I thought it would be interesting to see how the function is defined for non-integers, whereas the original system expects integer time intervals.

it is my understanding that the populations should start decreasing immediately

Well, you can just test that.

f[x_] := .6 f[x - 1] + .5 r[x - 1];
r[x_] := -.175 f[x - 1] + 1.2 r[x - 1];

(*initial conditions:*)
f[0] = 20;
r[0] = 50;

(*first generation:*)
{f[1], r[1]}
(* {37., 56.5} *)

Also, just look at the functions, for example f[x_] := .6 f[x - 1] + .5 r[x - 1]. That tells me that if the rabbit population is at least 80% of the fox population, then the fox population will go up.

But more abstractly, the sign of the eigenvalue doesn't really tell you much, because you could just take the negative and reverse the eigenvectors.

one would expect both the Foxes and Rabbits to go extinct

They do. Both populations start to decrease somewhere around the 9th generation, and things are looking pretty dire by 100 generations. :)

Thanks! I'll just point out that Gianluca's method is basically the standard way you'd do this. The only reason to use linear combinations of eigenvectors is to turn matrix multiplication into scalar multiplication (which could give performance improvement). Given the way you set up your original problem, I thought that's what you wanted.

Hi Gianluca;

In this predator - prey model, the f represents for "Foxes" and the r represents "Rabbits".

In the example that I submitted, I set the Predation value (the first value in the Rn+1 equation to - 0.175 which gives Eigenvalues of {.95, .85}. Since both these eigenvalues are less than 1 then over time both the Foxes and Rabbits should go extinct (as the provided graph in my attached notebook displays). My goal is to produce a plot to show this progression over several periods using Mathematica.

Thanks,

Mitch Sandlin