One can compute the difference between the new sum and MRB (m, that is) explicitly.
Start by rewriting Tanh[k] as an exponential in k, replace E^k by a new variable r, and find the general form of the series coefficients for this new expression near infinity (when E^k is large, so is r, so we expand still at infinity).
tpoly = TrigToExp[Tanh[k]] /. E^(n_.*k) :> r^n
SeriesCoefficient[tpoly, {r, Infinity, n}]
(* Out[6]= (-(1/r) + r)/(1/r + r)
Out[7]= Piecewise[{{1, n == 0}, {(-I)^n + I^n, n > 0}}, 0] *)\
What this says, in effect, is that the difference between Tanh[k] and 1 is -2*Exp[-2*k]+2*Exp[-4*k]-2*Exp[-6*k]+2*Exp[-8*k]+... and this is actually easy to evaluate in terms of the exponential. (I note that this also could have been done more directly by manipulating 1-TrigToExp[Tanh[k]]. That would be the smart way, which is to say, it's the simple method I thought of after doing it the harder way above.)
innersum[k_] = 2*Sum[(-1)^n*Exp[-2*k*n], {n, Infinity}]
(* Out[15]= -(2/(1 + E^(2 k))) *)
Now we have to evaluate an alternating sum of these over k. Sum does not directly give an exact form but we get a good numeric approximation with NSum.
NSum[(-1)^k*innersum[k], {k, Infinity}, WorkingPrecision -> 30, Method -> "AlternatingSigns"]
(* Out[32]= 0.206787942375363103764743643359 *)
So we expect the difference between m and the altered sum to be this amount. We actually can get an exact form if we split explicitly into odd and even summands.
odds = Sum[innersum[k], {k, 1, Infinity, 2}]
(* 1/2 (-I \[Pi] - Log[-1 + E^4] - QPolyGamma[0, 1/4 (2 - I \[Pi]), E^4]) *)
evens = Sum[innersum[k], {k, 2, Infinity, 2}]
(* Out[37]= 1/2 (2 - I \[Pi] - Log[-1 + E^4] - QPolyGamma[0, 1/4 (4 - I \[Pi]), E^4]) *)
diff = evens - odds;
N[sum, 30]
(* Out[41]= 0.206787942375363103764743643359 + 0.*10^-31 I *)
I do not agree that the approximation is notable. I will show one way to recover it in order to explain that opinion. We will form integer combinations of m, 1, the sum of interest (which is m-diff), and m*sum, and try to find an approximate integer relation between these. We then solve for sum in terms of m and obtain a linear rational function. This can be done using PSLQ but I am more familiar with LatticeReduce so I'll go that route.
bigmult = 10^14;
sum = m - diff;
bigm = Round[bigmult*m];
bigsum = Round[bigmult*sum];
bigprod = Round[bigmult*m*sum];
lat = {{bigm, 1, 0, 0, 0}, {bigsum, 0, 1, 0, 0}, {bigprod, 0, 0, 1,
0}, {bigmult, 0, 0, 0, 1}};
redlat = LatticeReduce[lat];
vec = First[redlat]
(* Out[428]= {1099, 270, 490, 407, -40} *)
What this means is that the following gives 0.
vec.{-1, bigm, bigsum, bigprod, bigmult}
(* Out[429]= 0 *)
Divide by bigmult and we have an approximate integer relation between m', sum, m*sum, and 1. we find it as below (and recover the given approximation as claimed).
approxdiff =
newsum /.
First[Solve[Rest[vec].{mrb, newsum, newsum*mrb, 1} == 0, newsum]]
(* Out[431]= -((10 (-4 + 27 mrb))/(490 + 407 mrb)) *)
Why do I see this as not particularly notable? It is because I expect lattice reduction to do this. Specifically, given a column of n entries each around m digits, augmented by an identity matrix, I expect the "smallest" row in the reduced lattice (the first row) to have entries all in the ballpark of m/n digits (really n+1 since they tend to spread evenly and sum to m over the n+1 rows, but allow a bit of slop here since this is anyway just a crude estimate). Upshot being, those values being 3 digits, around 15/5, is not so surprising.
