Hi,

does this work for you?

Manipulate[Show[Plot[{2 x, (6 - x)*5}, {x, 0, 6}, PlotRange -> {{-1, 7}, {-5, 32}}, ImageSize -> Large, Epilog -> {Black, PointSize[0.03], Point[{a, (6 - a)*5}], Point[{a, a*2}]}, PlotStyle -> {Thin, Automatic, Red, Dashed}, GridLines -> {Table[i, {i, 1, 5}], Table[2 i, {i, 1, 5}]}], 
ListPlot[Table[{i, 2 i}, {i, 5}], PlotMarkers -> {"X"}, Ticks -> {Table[i, {i, 1, 5}], Table[2 i, {i, 1, 5}]}, PlotRange -> {{-1, 7}, {-5, 32}}, ImageSize -> Large]], {{a, 30/7},0, 6}]

Cheers,

M.

FYI - PlotStyle -> {Thin, Automatic, Red, Dashed} plots a Blue line. Don't know why ???

I suppose that you need to wrap the options into a "Directive":

Manipulate[
 Show[Plot[{2 x, (6 - x)*5}, {x, 0, 6}, 
   PlotRange -> {{-1, 7}, {-5, 32}}, ImageSize -> Large, 
   Epilog -> {Black, PointSize[0.03], Point[{a, (6 - a)*5}], 
     Point[{a, a*2}]}, 
   PlotStyle -> Directive[Thick, Red, Automatic, Dashed], 
   GridLines -> {Table[i, {i, 1, 5}], Table[2 i, {i, 1, 5}]}], 
  ListPlot[Table[{i, 2 i}, {i, 5}], PlotMarkers -> {"X"}, 
   Ticks -> {Table[i, {i, 1, 5}], Table[2 i, {i, 1, 5}]}, 
   PlotRange -> {{-1, 7}, {-5, 32}}, ImageSize -> Large]], {{a, 30/7},
   0, 6}]

I have substituted "Thin" by "Thick" do see it a bit better.

Cheers,

M.

Marco is right. PlotStyle -> {Thin, Automatic, Red, Dashed} plots the first line Thin, the second Automatic, the third Red, and the fourth Dashed. For each line, all other properties keep their default values, so the thickness of lines 2, 3 and 4 is the standard one, the colours are the standard ones except for line 3, and so forth. (If your plot has less than 4 lines, you won't see all these styles, so it may look even more confusing.) By the way, if you do need multiple styles for different functions, you can use Directive inside a list of styles as well, such as PlotStyle->{Red,Directive[Green,Dashed],Blue}.