Perfect!

It is very interesting to know what is the cause of this situation...

It seems very strange such a big time difference for the function LengthWhile.

It is the worst choice!

In[1]:= tList = RandomChoice[{"a", "b", "c"}, 1000000];
tList[[777777]] = 1;

In[3]:= Position[NumericQ /@ tList, True][[1]] // AbsoluteTiming
Position[tList, _?NumericQ, 1] // AbsoluteTiming
Position[tList, _?(NumericQ[#] &), 1] // AbsoluteTiming
FirstPosition[tList, _?NumericQ, 1] // AbsoluteTiming
FirstCase[tList, _?NumericQ] // AbsoluteTiming
SelectFirst[tList, NumericQ] // AbsoluteTiming
(LengthWhile[tList, Not@*NumericQ] + 1) // AbsoluteTiming

Out[3]= {0.369993, {777777}}

Out[4]= {0.39994, {{777777}}}

Out[5]= {0.820059, {{777777}}}

Out[6]= {0.32599, {777777}}

Out[7]= {0.302233, 1}

Out[8]= {0.211421, 1}

Out[9]= {2.50185, 777777}

In[10]:= BarChart@{
   Position[NumericQ /@ tList, True][[1]] // AbsoluteTiming,
   Position[tList, _?NumericQ, 1] // AbsoluteTiming,
   Position[tList, _?(NumericQ[#] &), 1] // AbsoluteTiming,
   FirstPosition[tList, _?NumericQ, 1] // AbsoluteTiming,
   FirstCase[tList, _?NumericQ] // AbsoluteTiming,
   SelectFirst[tList, NumericQ] // AbsoluteTiming,
   (LengthWhile[tList, Not@*NumericQ] + 1) // AbsoluteTiming
   }[[All, 1]]

I just found out there is also SelectFirst, if you don't want the index but rather the element itself...

Absolutely well explained by Bill. Only for the simplicity it may be observed additionally that

In[1]:= Position[{0, -1 + x^2 y^2, -x^3 + 2 x^2 y + x^5 y^2}, _?NumericQ, 1]

Out[1]= {{1}}

In[2]:= Position[{0, -1 + x^2 y^2, -x^3 + 2 x^2 y + x^5 y^2}, _?(NumericQ[#] &), 1]

Out[2]= {{1}}

In[3]:= FirstPosition[{0, -1 + x^2 y^2, -x^3 + 2 x^2 y + x^5 y^2}, _?NumericQ, 1]

Out[3]= {1}

Perhaps start simply and avoid the use of shortcut notation when you aren't sure how things work

In[1]:= Map[NumericQ, {0, -1 + x^2 y^2, -x^3 + 2 x^2 y + x^5 y^2}]

Out[1]= {True, False, False}

and thus you would probably want to get the position of the first False.

There is a new function FirstPosition mentioned at the bottom of the help page on Position

In[2]:= FirstPosition[Map[NumericQ, {0, -1 + x^2 y^2, -x^3 + 2 x^2 y + x^5 y^2}], False]

Out[2]= {2}

Now can we perhaps understand why your _?NumericQ[#] & didn't work? The & turned all that into a function and Position is looking for a pattern as the third argument, not a function.

We can use a pattern with a condition that only matches numeric items, this way

In[3]:= Position[{0, -1 + x^2 y^2, -x^3 + 2 x^2 y + x^5 y^2}, z_ /; NumericQ[z]]

Out[3]= {{1}, {2, 1}, {2, 2, 1, 2}, {2, 2, 2, 2}, {3, 1, 1}, {3, 1, 2, 2}, {3, 2, 1}, {3, 2, 2, 2}, {3, 3, 1, 2}, {3, 3, 2, 2}}

which does successfully find the position of numeric items, but matches those at every level and that doesn't look like what you were looking for. You could augment that with a level argument like this

In[3]:= Position[{0, -1 + x^2 y^2, -x^3 + 2 x^2 y + x^5 y^2}, z_ /; NumericQ[z], 1]

Out[3]= {{1}}

which shows that only the first item in the list is numeric.

Perhaps you can use some of these ideas to explore further

In[1]:= Position[NumericQ /@ {0, -1 + x^2 y^2, -x^3 + 2 x^2 y + x^5 y^2}, True][[1]]

Out[1]= {1}