Plot this result from Reduce?

Questions
, ,
1

In[8]:= res =
Reduce[(x1 + I x2)^4 + (x2 + I x1)^4 == 0 && Im[x1] == 0 &&
Im[x2] == 0, {x1, x2}]

Out[8]= (x1 < 
    0 && (x2 == -Sqrt[3 x1^2 + 2 Sqrt[2] Sqrt[x1^4]] || 
     x2 == -Sqrt[3 x1^2 - 2 Sqrt[2] Sqrt[x1^4]] || 
     x2 == Sqrt[3 x1^2 - 2 Sqrt[2] Sqrt[x1^4]] || 
     x2 == Sqrt[3 x1^2 + 2 Sqrt[2] Sqrt[x1^4]])) || (x1 == 0 && 
   x2 == 0) || (x1 > 
    0 && (x2 == -Sqrt[3 x1^2 + 2 Sqrt[2] Sqrt[x1^4]] || 
     x2 == -Sqrt[3 x1^2 - 2 Sqrt[2] Sqrt[x1^4]] || 
     x2 == Sqrt[3 x1^2 - 2 Sqrt[2] Sqrt[x1^4]] || 
     x2 == Sqrt[3 x1^2 + 2 Sqrt[2] Sqrt[x1^4]]))
2

Best way is:

ContourPlot[(x1 + I x2)^4 + (x2 + I x1)^4 == 0, {x1, -2, 2}, {x2, -2, 2}, MaxRecursion -> 4]

ssss.png
ssss.png373×367 4.85 KB

Or manualy:

  sol = LogicalExpand[Reduce[(x1 + I x2)^4 + (x2 + I x1)^4 == 0 && Im[x1] == 0 && Im[x2] == 0, {x1, x2}]]
  p1 = ContourPlot[Evaluate[{sol[[2, 1]], sol[[4, 1]], sol[[6, 1]], sol[[8, 1]]}], {x1, -2, 2}, {x2, -2, 2}, MaxRecursion -> 4, 
          RegionFunction -> Function[{x1, x2}, x1 > 0]]
  p2 = ContourPlot[Evaluate[{sol[[3, 1]], sol[[5, 1]], sol[[7, 1]], sol[[9, 1]]}], {x1, -2, 2}, {x2, -2, 2}, MaxRecursion -> 4, 
          RegionFunction -> Function[{x1, x2}, x1 < 0]]
  Show[{p1, p2}]

aaaa.png
aaaa.png379×375 5.43 KB

3

x1 and x2 are real?

You can plug in the equation immediately:

ContourPlot[{(x1 + I x2)^4 + (x2 + I x1)^4 == 0}, {x1, -100, 100}, {x2, -100, 100}]

For other kinds of plots, you might want to look at the function ToRules, or if it is region that satisfies the equation (bigger/smaller than something) you can use RegionPlot…

4

I was hoping for a general method.

5

ImplicitRegion look promising

In[14]:= res = 
 Reduce[(x1 + I x2)^4 + (x2 + I x1)^4 == 0 && Im[x1] == 0 && 
   Im[x2] == 0, {x1, x2}]

Out[14]= (x1 < 
    0 && (x2 == -Sqrt[3 x1^2 + 2 Sqrt[2] Sqrt[x1^4]] || 
     x2 == -Sqrt[3 x1^2 - 2 Sqrt[2] Sqrt[x1^4]] || 
     x2 == Sqrt[3 x1^2 - 2 Sqrt[2] Sqrt[x1^4]] || 
     x2 == Sqrt[3 x1^2 + 2 Sqrt[2] Sqrt[x1^4]])) || (x1 == 0 && 
   x2 == 0) || (x1 > 
    0 && (x2 == -Sqrt[3 x1^2 + 2 Sqrt[2] Sqrt[x1^4]] || 
     x2 == -Sqrt[3 x1^2 - 2 Sqrt[2] Sqrt[x1^4]] || 
     x2 == Sqrt[3 x1^2 - 2 Sqrt[2] Sqrt[x1^4]] || 
     x2 == Sqrt[3 x1^2 + 2 Sqrt[2] Sqrt[x1^4]]))

In[15]:= RegionPlot[ImplicitRegion[res, {x1, x2}]]

K3.jpg
K3.jpg360×352 11 KB

6

No idea RegionPlot could also do 1D regions (lines)!

7

I think it only does that for an ImplicitRegion

8

Graph of y^2 = x((x^2)-1) with x and y complex

In[1]:= eqns = y^2 - x (x^2 - 1) == 0 /. {x -> x1 + I x2, y -> y1 + I y2} // 
  ComplexExpand

Out[1]= x1 - x1^3 + 3 x1 x2^2 + y1^2 - y2^2 + I (x2 - 3 x1^2 x2 + x2^3 + 2 y1 y2) == 0

In[2]:= eqre = x1 - x1^3 + 3 x1 x2^2 + y1^2 - y2^2 == 0;
eqim = x2 - 3 x1^2 x2 + x2^3 + 2 y1 y2 == 0;

 Imaginary part of x = 0

In[5]:= Show[DiscretizeRegion[
  ImplicitRegion[(eqre && eqim) /. 
    x2 -> 0, {{x1, -3, 3}, {y1, -3, 3}, {y2, -3, 3}}], 
  MaxCellMeasure -> 10^-3], Boxed -> True, Axes -> True, ImageSize -> Medium]

complex_torus.jpg
complex_torus.jpg360×489 12.8 KB