Plotting vector points efficiently?

Questions
,
1

Is there a better way of plotting a series of vector points (x,y) than using the Graphics[] command, see attached. I am just trying to visualize all the individual vector points to get an idea of the total graph; however my method seems awful crude and not very visually appealing?

p1=Graphics[{PointSize[Large],Black,Point[{0,0}],Text["(0,0)",{0,0.1}]}];
p2=Graphics[{PointSize[Large],Black,Point[{4,0}],Text["(4,0)",{4,0.1}]}];
p3=Graphics[{PointSize[Large],Black,Point[{4,2}],Text["(4,2)",{4,2.1}]}];
p4=Graphics[{PointSize[Large],Black,Point[{0,2}],Text["(0,2)",{0,2.1}]}];

Show[p1,p2,p3,p4]
2

Hi,

if this is a list of points:

list = {{0, 0}, {4, 0}, {4, 2}, {0, 2}};

then this would generate your plot:

Graphics[{PointSize[Large], Black, Point[#], Text["(" <> StringTake[ToString[#], 2 ;; -2] <> ")", # + {0, 0.1}]} & /@ list]

ScreenShot2016-08-31at17.52.33.png
ScreenShot2016-08-31at17.52.33.png376×201 1.17 KB

Cheers,

Marco

PS: The labelling can be done more elegantly.

3

I’m late but I believe the labelling here should satisfy a more elegant approach.

pts = {
   {0, 0}, {4, 0}, {4, 2}, {0, 2}
   };

Graphics[{
  {PointSize[Large], Point[pts]},
  Inset[#, # + {0, 0.2}] & /@ pts
  }]

Alternatively, moving away from Graphics,

ListPlot[Labeled[#, #] & /@ pts, Axes -> False]

and generally, for any list of vectors

plotVec = 
  Function[{pts}, 
   ListPlot[Labeled[#, #] & /@ pts, Axes -> False, PlotRange -> All]];

all produce the same output.

4

Hi Ben,

you are right. But your labels contain curly brackets. Much of my labelling code is to replace them by round ones. Also I was not sure whether it was relevant that the labels be text like in the OP. I also wanted to maintain the Graphics structure.

Your Graphics suggestion with the parenthesis replaced could look like this:

pts = {{0, 0}, {4, 0}, {4, 2}, {0, 2}};

Graphics[{{PointSize[Large], Point[pts]}, 
  Inset[StringReplace[
      ToString[#], {"{" -> "(", "}" -> ")"}], # + {0, 0.2}] & /@ pts}]

or this if the Text is not required:

Graphics[{{PointSize[Large], Point[pts]}, Inset[MatrixForm[{#}], # + {0, 0.1}] & /@ pts}]

Cheers,

M.

5

Ah, I missed the detail of the parenthesis vs. brackets in the OP. Thanks.

6

You may try ListPlot with Labeled:

pts = {{0, 0}, {1/2, 1/2}, {1, 1}};
ListPlot[Map[Labeled[#, TraditionalForm[{#}]] &, pts]]