Here's a little demo of the concept. I did it with LTemplate for convenience, but of course you do not need LTemplate for this.

In[1]:= << LTemplate`

In[2]:= SetDirectory@CreateDirectory[];

In[3]:= tem = LClass["Test",
   {LFun["messageQ", {}, True | False],
    LFun["getMessage", {}, "UTF8String"],
    LFun["sqrt", {Real}, Real]}
   ];

In[4]:= code = "
  #include <cmath>

  class Test {
    const char *message_text;

    void setMessage(const char *msg) {
     message_text = msg;
    }

  public:
    bool messageQ() const { return message_text != nullptr; }

    const char *getMessage() {
     const char *tmp = message_text;
     message_text = nullptr;
     return tmp;
    }

    double sqrt(double x) {
     if (x < 0) {
         setMessage(\"Argument must be non-negative.\");
         throw mma::LibraryError();
     }
     return std::sqrt(x);
    }
  };
  ";
Export["Test.h", code, "String"];

In[6]:= CompileTemplate[tem]

During evaluation of In[6]:= Current directory is: /private/var/folders/31/l_62jfs110lf0dh7k5n_y2th0000gq/T/m000003189471

During evaluation of In[6]:= Unloading library Test ...

During evaluation of In[6]:= Generating library code ...

During evaluation of In[6]:= Compiling library code ...

Out[6]= "/Users/szhorvat/Library/Mathematica/SystemFiles/\
LibraryResources/MacOSX-x86-64/Test.dylib"

In[7]:= LoadTemplate[tem]

In[8]:= obj = Make["Test"];

In[9]:= General::fail = "Library failed with: ``";

In[10]:= check[head_][_LibraryFunctionError] :=
 (Message[
   head::fail,
   If[obj@"messageQ"[], obj@"getMessage"[], "Unknown error"]
   ]; $Failed)
check[head_][x_] := x

In[12]:= sqrt[x_?Internal`RealValuedNumericQ] :=check[sqrt]@obj@"sqrt"[x]

In[13]:= sqrt[4]
Out[13]= 2.

In[14]:= sqrt[-1]

During evaluation of In[14]:= sqrt::fail: Library failed with: Argument must be non-negative.

Out[14]= $Failed

When you use the WolframLibraryData::Message method with a "tag", the message issued uses LibraryFunction as the function; it calls Message[ MessageName[ LibraryFunction, "tag"]]. So it's less versatile than the math link version.

src = "
  #include \"WolframLibrary.h\"
  
  DLLEXPORT int issueMessages(WolframLibraryData libData,
  			mint Argc, MArgument *Args, MArgument Res) {
  	libData->Message(\"rnoset\");
  	return LIBRARY_RANK_ERROR;
  }
  
  ";

<< CCompilerDriver`
lib = CreateLibrary[src, "messageLibrary"];
messageFunc = LibraryFunctionLoad[lib, "issueMessages", {}, "Void"];

This function generates two messages, one from the libData->Message(\"rnoset\"); call and one from returning a certain value.

In[5]:= messageFunc[]

During evaluation of In[5]:= LibraryFunction::rnoset: The function was executed but it failed to set a value for the result.

During evaluation of In[5]:= LibraryFunction::rnkerr: An error caused by inconsistent tensor rank was encountered evaluating the function issueMessages.

Out[5]= LibraryFunctionError["LIBRARY_RANK_ERROR", 2]

So in this example, nowhere does the library does not know the symbol name messageFunc - in your example the library never has access to the symbol name MyFunction.