Message Boards Message Boards

3D version of the built-in VoronoiDiagram

Posted 5 years ago

Open in Cloud | See Original | Download to Desktop via Attachments Below

enter image description here

Attachments:
POSTED BY: Greg Hurst
12 Replies
Posted 3 years ago

Chip and me were discussing his function a few days ago, when I mentioned to him that this can be used to implement Lloyd relaxation in 3D. In the spirit of this 2D Lloyd implementation and this spherical Lloyd implementation, I present the following:

VoronoiCells[pts_List, ibds : (_?MatrixQ | Automatic) : Automatic] /; 
             MatrixQ[pts, Internal`RealValuedNumericQ] && 
             2 <= Last[Dimensions[pts]] <= 3 := 
   Module[{bds, dm, conn, adj, lc, pc, cpts, hpts, hns, hp, vcells},
          If[ibds === Automatic,
             bds = CoordinateBounds[pts, Scaled[0.1]],
             bds = ibds];
          dm = DelaunayMesh[pts];
          conn = dm["ConnectivityMatrix"[0, 1]];
          adj = conn . Transpose[conn];
          lc = conn["MatrixColumns"]; pc = adj["MatrixColumns"];
          cpts = MeshCoordinates[dm];
          vcells = Table[hpts = PropertyValue[{dm, {1, lc[[i]]}}, MeshCellCentroid];
                         hns = Transpose[Transpose[cpts[[DeleteCases[pc[[i]], i]]]] - cpts[[i]]];
                         hp = MapThread[HalfSpace, {hns, hpts}];
                         BoundaryDiscretizeGraphics[#, PlotRange -> bds] & /@ hp,
                         {i, MeshCellCount[dm, 0]}];
          AssociationThread[cpts, RegionIntersection @@@ vcells]]

BlockRandom[SeedRandom["voronoi"];
            pts = RandomReal[{-1, 1}, {32, 3}]];

lloyd = With[{maxit = 50,(*maximum iterations*)
              tol = 0.005 (*distance tolerance*)},
             FixedPointList[Function[pts, 
                                     RegionCentroid /@ Values[VoronoiCells[pts,
                                                       {{-1, 1}, {-1, 1}, {-1, 1}}]]],
                            pts, maxit,
                            SameTest -> (Max[MapThread[EuclideanDistance,
                                                       {#1, #2}]] < tol &)]];

frames = Function[pt, Show[MapIndexed[BoundaryMeshRegion[#, 
                           MeshCellStyle -> {1 -> Black, 
                                             2 -> {Opacity[0.5],
                                                   ColorData[112] @@ #2}}] &, 
                                      Values[VoronoiCells[pt,
                                                          {{-1, 1}, {-1, 1}, {-1, 1}}]]], 
                          Graphics3D[{PointSize[Large], Point[pt]}],
                          Axes -> True, Boxed -> True,
                          Method -> {"RelieveDPZFighting" -> True}]] /@ lloyd;

ListAnimate[frames]

3D Lloyd animation

POSTED BY: J. M.

Thanks for this function! will be very useful actually!

The code can be slightly simplified: MinMax also has padding built in, second argument:

MinMax[Â…,paddingspec]
POSTED BY: Sander Huisman
Posted 5 years ago

Some time ago, I submitted this Wolfram Demonstration: Three-Dimensional Voronoi Mesh but, since I did not use the Regions functionality, I had to limit it to 2D cross sections of the 3D mesh. Hope they includeChip's excellent function in V12?

POSTED BY: Erik Mahieu

I spent nearly a week programming this in Mathematica (v.5, as I recall) around 2001 for half of Figure 4.10 in my book Pattern classification (2nd ed). At that time, there was no Opacity[] functionality either. I believe mine is the first book to include such a figure. I am so glad Wolfram has included this functionality, and thank Chip Hurst for his contributions to it. It looks great!

POSTED BY: David Stork

A most excellent function and one that is needed. Thanks ! the function should be scaled up and made part of version 12.0 !

POSTED BY: Ali Hashmi

Very nice. Have you thought about submitting this to the function repository?

Also, do you know if this has a relationship to power diagrams?

Posted 5 years ago

Aha, thanks!

POSTED BY: Greg Hurst

enter image description here - Congratulations! This post is now a Staff Pick as distinguished by a badge on your profile! Thank you, keep it coming, and consider contributing your work to the The Notebook Archive!

POSTED BY: Moderation Team

Hi. This is very interesting. Is it possible to link the points with the face centres of their cells? It will be nice to visualise this.

Great post. Thanks Fotos Stylianou

POSTED BY: Fotos Stylianou

He's had to think about contributing it to the WFR; I put in a request a couple of days ago.

POSTED BY: Daniel Lichtblau

I hope that such an important function can go beyond the function repository and can be incorporated in the next Mathematica release.

POSTED BY: Ali Hashmi

I have been using your method with more points (like 1000) and it has some issues due to probably an internal bug in BoundaryDiscretizeGraphics. You may want to check my post here https://mathematica.stackexchange.com/questions/219100/weird-behaviour-with-boundarydiscretizegraphics

POSTED BY: Fotos Stylianou
Reply to this discussion
Community posts can be styled and formatted using the Markdown syntax.
Reply Preview
Attachments
Remove
or Discard

Group Abstract Group Abstract