A geometric way is to use InfiniteLine and RegionIntersection:

a = {0, 0}; b = {4, 0}; c = {2, 2 Sqrt[3]};
ab3 = Table[t*a + (1 - t) b, {t, {1/4, 1/2, 3/4}}];
ac3 = Table[t*a + (1 - t) c, {t, {1/4, 1/2, 3/4}}];
bc3 = Table[t*b + (1 - t) c, {t, {1/4, 1/2, 3/4}}];
ab3LinesParallelToAC = Table[InfiniteLine[pt, c - a], {pt, ab3}];
ab3LinesParallelToBC = Table[InfiniteLine[pt, b - c], {pt, ab3}];
ac3LinesParallelToAB = Table[InfiniteLine[pt, a - b], {pt, ac3}];
Graphics[{{Gray, Polygon[{a, b, c}]}, ab3LinesParallelToAC, Green, 
  ab3LinesParallelToBC, Red, ac3LinesParallelToAB, Blue, 
  PointSize[Large], 
  Outer[RegionIntersection, ab3LinesParallelToAC, 
   ab3LinesParallelToBC], 
  Outer[RegionIntersection, ab3LinesParallelToAC, 
   ac3LinesParallelToAB],
  Outer[RegionIntersection, ab3LinesParallelToBC, 
   ac3LinesParallelToAB]}]

IGraph/M has a function to generate triangular graphs, with coordinates attached.

<<IGraphM`
g = IGTriangularLattice[4, VertexLabels -> "Name"]

Get the coordinates like so:

In[54]:= GraphEmbedding[g]
Out[54]= {{1/2, (3 Sqrt[3])/2}, {0, Sqrt[3]}, {1, Sqrt[3]}, {-(1/2), 
  Sqrt[3]/2}, {1/2, Sqrt[3]/2}, {3/2, Sqrt[3]/2}, {-1, 0}, {0, 0}, {1,
   0}, {2, 0}}

They can be scaled, translated, etc. with ScalingTransform, TranslationTransform, etc. to deal with triangles of different dimensions.

You can look up the implementation in https://github.com/szhorvat/IGraphM/blob/master/IGraphM/DeterministicGenerators.m which you might find helpful to build on.