One way to visualize

DiscretizeRegion[ImplicitRegion[x^2 + y^2 + z^2 <= 1, {x, y, z}]]

DiscretizeRegion[ImplicitRegion[x^2 + y^2 + z^2 <= 1 && z >= 0 && x >= 0, {x, y, z}]]

To determine ?, ? limits, just convert x, y, z ranges from cartesian to spherical coordinates. Can you give an example of "more complex planes / constraints"? You can use Solve to determine the intersection points / ranges for more complex situations. See this example.

If you want to calculate the constraints for the angles you can do it this way:

cond1 = Sqrt[x^2 + y^2 + z^2] <= 1 && z > 0;
cond2 = Sqrt[x^2 + y^2 + z^2] <= 1 && x > 0 && z > 0;

If you replace x,y,z with there representation in spherical coordinates, you get conditions for r and some trigonometric expressions:

cond3 = Simplify[
  cond1 /. Thread[{x, y, z} -> 
     CoordinateTransform[
      "Spherical" -> "Cartesian", {r, \[Theta], \[Phi]}]], r > 0]

"Reduce" can be used to derive finally constraints for the angles themself:

Reduce[cond3 && 0 <= \[Theta] <= \[Pi], \[Theta]]

cond4 = Simplify[
  cond2 /. Thread[{x, y, z} -> 
     CoordinateTransform[
      "Spherical" -> "Cartesian", {r, \[Theta], \[Phi]}]], r > 0]

Reduce[cond4 && 0 <= \[Theta] <= \[Pi] && 
  0 <= \[Phi] <= 2 \[Pi], {\[Phi], \[Theta]}]

Using region functionalities you can easily compute the volumes and display the defined regions:

 reg1 = ImplicitRegion[cond1, {x, y, z}];
 reg2 = ImplicitRegion[cond2, {x, y, z}];

RegionMeasure can be used to compute the volume:

 {RegionMeasure[reg1, 3], RegionMeasure[reg2, 3]}

Region will display the defined regions:

  {Region[reg1], Region[reg2]}