Thanks Diego for this analysis, it is very instructive. However as you point out at the beginning this depends upon a voluntary effort by nearly 18000 law enforcement agencies. I did a similar analysis in 2015 related to the number of black deaths by police and found that of the 18000 law agencies only 1200 bothered to report deaths at all. The US Bureau of Justice Statistics (BJS) also attempted to do a review but found that all attempts at verification failed because even those police departments which reported gave different results when queried at later dates, see http://www.bjs.gov/index.cfm?ty=dctp&tid=7. So these UCR reports are highly biased. America is pretty much unique amongst western countries in that it doesn't have compulsory data collection from all law enforcement offices. Even China collects data from its crime bureaus but it doesn't release it publicly. The best reference for US deaths due to the police is the Guardian's ongoing report called the Counted, see https://www.theguardian.com/us-news/series/counted-us-police-killings.

Data for 2017 is available here. The downloadable Excel is in a different format and Violent / Property are missing for some MSA's

data = Import[
   "~/Documents/Mathematica/US Crime/2017-table-6.xls", {"Dataset", 1, ;; -9}, 
   "SkipLines" -> 3, HeaderLines -> 1];

extractRate = 
  data[Select[
    StringLength[StringTrim[#"Counties/principal cities"]] == 0 ||
    #"Counties/principal cities" == "Rate per 100,000 inhabitants" &]];

crimeRate = 
  extractRate // Normal // Partition[#, 2] & // 
    Map[Merge[#, (SelectFirst[StringLength@StringTrim@ToString@# > 0 &])] &] // Dataset;

cityState[text_] := 
 Module[{city, state, split = StringSplit[text, ","]},
  city = First@split;
  state = First@StringSplit@split[[2]];
  <|"City" -> city, "State" -> state, "CityState" -> city <> ", " <> state|>]

BubbleChart[
 crimeRate[
  Select[#"Population" >= 400000 && Not@MissingQ[#"Property\ncrime"] &&
      Not@MissingQ[#"Violent\ncrime"] &], 
  Callout[{#"Property\ncrime", #"Violent\ncrime", #"Population"}, 
    Style[#"CityState", FontSize -> 9]] &], PlotTheme -> "Detailed", 
 FrameLabel -> {"Property Crime Rate (per 100k)", 
   "Violent Crime Rate (per 100k)"}, PlotTheme -> "Detailed", 
 PlotLabel -> "Crime Rates by City/State 2017", AspectRatio -> 1/3, 
 ImageSize -> Full]

Albuquerque, NM increased significantly between 2014 and 2017 and is by far the highest for property and second highest for violent crimes. In the news.

I live in St. Louis which frequently appears in crime statistics as one of the "most dangerous" cities. While city lines are important for the agencies reporting this data, they can lead to misleading statistics. Large metropolitan areas with small central cities tend to rank higher (more crime) on these lists that similar metropolitan areas where the central city is larger. This is not necessarily because there is more crime, but because the city include less of the affluent suburbs. I'm not suggesting you are doing anything wrong in your post, just that we can go further.

Luckily there is more data to help!

https://www.census.gov/data/tables/time-series/demo/popest/2010s-total-metro-and-micro-statistical-areas.html

The census defines "Metropolitan Statistical Area" to try to measure exactly what it says, the metropolitan area. The data from that link does not include crime stats, but we can use it along with the data you posted to see if the hypothesis I laid out above may be true.

msadata = 
  Import["/Users/bobs/Downloads/cbsa-est2018-alldata.csv", "Dataset", 
   "HeaderLines" -> 1];
msa = msadata[Select[#LSAD === "Metropolitan Statistical Area" &]]

I made a little utility to handle names and included a few more agencies from your Dataset (I wanted St. Louis).

agencyToName[str_] := StringReplace[str, {" Police Dept" -> "", " City" -> "", 
" Sheriff Department" -> ""}];
notsmall = usCrimes2014[Select[#Population >= 200000 &]]

I made this somewhat hacky map from agency names to MSA names, city names seems to be unique enough that it worked pretty well.

msanames = Normal[msa[All, "NAME"]]; 
agencyToMSAMap = 
 DeleteMissing[
  AssociationMap[
   Function[name, 
    SelectFirst[msanames, StringContainsQ[#, agencyToName@name] &]], 
   Normal@notsmall[All, "Agency"]]]

I combined the data into a single Dataset

combinestats[crimedata_] := 
 Association[
   Normal /@ {KeyTake[
      crimedata, {"Agency", "Population", "PropertyCrimeRate", 
       "ViolentCrimeRate"}], 
     KeyTake[SelectFirst[
       msa, #NAME === 
         agencyToMSAMap[
          crimedata["Agency"]] &], {"POPESTIMATE2014"}]}] /; 
  KeyExistsQ[agencyToMSAMap, crimedata["Agency"]]
combinestats[_] := Missing[]

mydata = DeleteMissing[combinestats /@ notsmall][
  Select[NumberQ[Total[KeyDrop[#, "Agency"]]] &]]

Finally I added a second set of bubbles to your plot so each city has both the city population and the MSA population:

BubbleChart[{Normal@
   mydata[All, 
    Callout[{#PropertyCrimeRate, #ViolentCrimeRate, #POPESTIMATE2014},
       agencyToName[#Agency]] &],
  Normal@mydata[
    All, {#PropertyCrimeRate, #ViolentCrimeRate, #Population} &]}, 
 FrameLabel -> {"Property Crime Rate (per 100k)", 
   "Violent Crime Rate (per 100k)"}, PlotTheme -> "Detailed", 
 PlotLabel -> "Crime Rates by Policy Department (2014)", 
 PlotTheme -> "Detailed", AspectRatio -> 1/3, ImageSize -> Full]

If my hypothesis is correct then the highest crime cities (top right) will show lots of blue around their yellow and in fact we see a lot of them are that way (Atlanta, St. Louis, Detroit). However, there are cities in the lower crime area that also show a lot of blue. It turns out these are all not the major center of their MSA (Newark is in with New York, Anaheim with L.A., Scottsdale with Phoenix, etc). So the primary idea checks out that city crime data (while important for the agencies reporting it) is screwed by municipal lines and does not reflect a standard measurement for comparing the crime rates of two areas that people outside of those agencies probably really care about.

Note: Just like every year in football, something went wrong with Cleveland. The yellow is bigger than the blue. Maybe there are two Clevelands in the MSA names?

it looks like @Rohit Namjoshi already did it with the correct data. However that data looks like it has important holes when not all of the municipalities in an MSA report full data.