Szabolcs,

Sorry that my notebook wasn't formatted correctly. The function was there, but it was at the bottom of the page. I've attached a new notebook which has everything in the correct order and all self-contained within one cell. I hope that helps.

I'm not totally sure what you meaning by benchmarking the function.

In the notebook that I attached you can see that the FindMinimum function takes 28.766584 seconds. I opened that exact same notebook in Mathematica 7 and it took 0.328 seconds. So, it seems like something different is going on with the function, but I can seem to fix it.

Again, any help anyone could provide would be greatly appreciated.

Thanks,

Matty

Attachments:

Thanks Daniel.

Do you think there is any way to make it run faster in the current version. I am running a Short Course on my Strain Analysis program at the Colorado School of Mines on Sunday and it would be nice if I could get the programs to run faster so the participants will have time to actually run through the entire process of strain analysis. I don't know if there are any options for the FindMinimum function that I could employ (in addition to the Gradient->"FiniteDifference" which I've already added) that might help it run more quickly.

Thanks for the help and sending in the report.

Matty

Actually I do have a speedup. The constraints state in effect that all three roots of a parametrized cubic are nonnegative. Replace them with the constraints that all three coefficients of said cubic are of appropriate sign (so the constant and quadratic terms will be nonpositive, the linear coefficient nonnegative).

In[42]:= gam2^2 - 2*gam1*gam2*gam3 + gam1^2*lam1 + gam3^2*lam3 - 
   lam1*lam3 + (-1*gam1^2 - 1*gam2^2 - 1*gam3^2 + lam1 + lam3 + 
      lam1*lam3)*#1 + (-1 - 1*lam1 - 1*lam3)*#1^2 + #1^3 &[x]

Out[42]= gam2^2 - 2 gam1 gam2 gam3 + gam1^2 lam1 + gam3^2 lam3 - 
 lam1 lam3 + (-gam1^2 - gam2^2 - gam3^2 + lam1 + lam3 + 
    lam1 lam3) x + (-1 - lam1 - lam3) x^2 + x^3

In[46]:= mycons2 = {(-1 - lam1 - lam3) <= 
    0, (-gam1^2 - gam2^2 - gam3^2 + lam1 + lam3 + lam1 lam3) >= 0, 
   gam2^2 - 2 gam1 gam2 gam3 + gam1^2 lam1 + gam3^2 lam3 - lam1 lam3 <=
     0};

In[47]:= Timing[
 fm1 = FindMinimum[{errindex, 
    mycons2}, {lam1, .01}, {lam3, .11}, {gam1, 0.0}, {gam2, 
    0.0}, {gam3, 0.0}]]

Out[47]= {0.104000, {0.0308505996903, {lam1 -> 1.0254443981, 
   lam3 -> 9.42312324422, gam1 -> -0.182347311039, 
   gam2 -> 1.50192292523, gam3 -> -0.0452412524485}}}

Matty,

Glad that last post helped.

Here is what I had meant by using a penalty. It might be faster in some cases where the improved constraint setup remains slow. Also I did not try to adjust the method so that could perhaps give further speed gains.

I include my version of "errindex". I obtained it by multiple use of Chop. It might or might not improve the FindMinimum computation speed but at least it makes the code easier to read. I'd be surprised if this in any way lead to a worsened quality of result 9and if it did, that would indicate you're dealing with a numerically unstable computation).

errindex = (0.8988621286229235 - ((-1.*gam3^2 + 1.*lam1)^2)^(-1/
         4))^2 + (0.04410530083035308 + (1.*
         gam3)/((-1.*gam3^2 + 1.*lam1)^2)^(1/
          4))^2 + (1.114681824560056 - (1.*
         lam1)/((-1.*gam3^2 + 1.*lam1)^2)^(1/
          4))^2 + (0.3334610964453241 - 
      1./((-1.*gam1^2 + 1.*lam3)^2)^(1/
          4))^2 + (0.07055833545418581 + (1.*
         gam1)/((-1.*gam1^2 + 1.*lam3)^2)^(1/
          4))^2 + (3.013780286261509 - (1.*
         lam3)/((-1.*gam1^2 + 1.*lam3)^2)^(1/
          4))^2 + (0.4795936666881171 - (1.*
         gam2)/((-1.*gam2^2 + 1.*lam1*lam3)^2)^(1/
          4))^2 + (0.3499718837183906 - (1.*
         lam1)/((-1.*gam2^2 + 1.*lam1*lam3)^2)^(1/
          4))^2 + (3.5145968643500987 - (1.*
         lam3)/((-1.*gam2^2 + 1.*lam1*lam3)^2)^(1/4))^2;

errindex2 = 
  100*(Max[(-1 - lam1 - lam3), 0] - 
      Min[(-gam1^2 - gam2^2 - gam3^2 + lam1 + lam3 + lam1 lam3), 0] +
      Max[(gam2^2 - 2 gam1 gam2 gam3 + gam1^2 lam1 + gam3^2 lam3 - 
         lam1 lam3), 0]) + errindex;

Timing[
 fm1 = FindMinimum[
   errindex2, {lam1, .01}, {lam3, .11}, {gam1, 0.0}, {gam2, 
    0.0}, {gam3, 0.0}]]

During evaluation of In[55]:= FindMinimum::lstol: The line search decreased the step size to within the tolerance specified by AccuracyGoal and PrecisionGoal but was unable to find a sufficient decrease in the function. You may need more than MachinePrecision digits of working precision to meet these tolerances. >>

Out[55]= {0.120000, {0.0308505996903, {lam1 -> 1.02544451853, 
   lam3 -> 9.4231233029, gam1 -> -0.182347320429, 
   gam2 -> 1.50192314333, gam3 -> -0.0452412621552}}}