How about

Histogram[poisson = RandomVariate[PoissonDistribution[1], 1000000], {-1/2, Max[poisson] + 1/2, 1}]

Can you given an example of what you don't think you can get with the {xmin, xmax, dx} option? That option (in my limited imagination) would seem to cover all possibilities that one might want (at least with a constant binwidth).

For example, suppose for a dataset x (continuous or discrete) you want a specific binwidth dx and you want one of the bins to be centered at xc.

SeedRandom[12345];
x = RandomVariate[NormalDistribution[0, 1], 200];
dx = 3/4;  (* Desired binwidth *)
xc = 1.8;    (* One specific bin midpoint *)

{xmin, xmax} = MinMax[x];
xlow = xc - dx/2 - dx Floor[(xc + dx/2 - xmin)/dx];
xhigh = xc + dx/2 + dx Ceiling[(xmax - xc - dx/2)/dx];
Show[Histogram[x, {xlow, xhigh, dx}],
 ListPlot[{{{xmin, 0}}, {{xmax, 0}}, {{xc, 0}}},
  PlotStyle -> {Red, Green, Blue}, PlotLegends -> {"Min", "Max", "xc"}]]

The example I've given is very general and certainly most folks would opt for "nice" values for xc and dx with likely xc being a multiple of dx. But if you also only want tick marks at the center of the bins, then you'll likely need to specify the tick marks as in Eric Rimbey's answer.

Addition: From your responses and examples I'm guessing that you have data that takes on non-negative integer values and want to produce histogram bars that don't touch and you want to be in control of the width of the bars and you want the horizontal axis labels to be centered under the bars. That can be done (almost) automatically with the code I produced above. The limitations are that you need to specify the binwidth as a ratio of the form 1/2, 1/3, 1/4, 1/5, etc.

(* Generate data *)
SeedRandom[12345];
poisson = RandomVariate[PoissonDistribution[1], 1000000];

dx = 1/3;  (* Desired binwidth *)

(* Produce histogram *)
{xmin, xmax} = MinMax[poisson];
xc = poisson[[1]];  (* Choose any value in the dataset *)
xlow = xc - dx/2 - dx Floor[(xc + dx/2 - xmin)/dx];
xhigh = xc + dx/2 + dx Ceiling[(xmax - xc - dx/2)/dx];
Histogram[poisson, {xlow, xhigh, dx}]

I think there are two issues: (1) How to get done what you want to get done?, and (2) Should you be doing what you want?

To answer the second question one would need to know the purpose for your graphic. For the first part another option is to use the BarChart function:

SeedRandom[12345];
poisson = RandomVariate[PoissonDistribution[1], 500];
BarChart[Last[HistogramList[poisson]], BarSpacing -> 3,
 ChartLabels -> Range[Min[poisson], Max[poisson]]]

It finally dawned on me: I think you want the binwidth parameter to be the width of the bar as opposed to a width of a "bin" that might encompass more than one value.

I know these forums are typically "how to do something" rather than "should I do this?" but I think for graphics (and statistical analyses) it's critical to know what is the kind of message to the viewer that's desired. For example, I'm just not seeing the need for separating the bars or even to have bars. Here is a DiscretePlot:

DiscretePlot[Length[poisson] PDF[EmpiricalDistribution[poisson], s],
 {s, 0, Max[poisson]}, AxesOrigin -> {-0.5, 0}]

If something looks like a Graphics display, it very well might be, and if you look at the FullForm of your histogram, you'll see that the output is indeed a Graphics "object". That suggests that Histogram will accept the same options that Graphics does. There might be overrides or other imperfect matches, but basically you can expect to have the same control over the output that you would for Graphics. And the documentation for Histogram says this explicitly:

Histogram has the same options as Graphics with the following additions and changes: ...

One option that Graphics accepts is Ticks, and if I'm understanding your question, that's the relevant one for you. Look up the documentation for Ticks to get the specifics, but here's an example:

With[
 {poisson = RandomVariate[PoissonDistribution[1], 100]},
 Histogram[poisson, {1/2}, Ticks -> {Range[Min[poisson] + 1/4, Max[poisson] + 1/4, 1], Automatic}]]