Took a little different approach:

Module[
    {intype, in = {0, 0, 0}, xyzCoords = {}, latlongCoords, again = True, outtype},
    intype = ChoiceDialog["Type of input?", {"x,y,z" -> 1, "All" -> 2}];
    Switch[intype,
     1,
         While[again,
            in[[1]] = Input["What is the x coordinate?"];
            in[[2]] = Input["What is the y coordinate?"];
            in[[3]] = Input["What is the z coordinate?"];
            AppendTo[xyzCoords, in];
            again = ChoiceDialog["Enter more coords?", {"Yes" -> True, "No" -> False}]
        ],
     2, xyzCoords = Input[]
    ];
    latlongCoords = Table[GeoPositionXYZ[xyzCoords[[i]], "ITRF00"], {i, Length@xyzCoords}];
    latlongCoords = Table[GeoPosition@latlongCoords[[i]], {i, Length@xyzCoords}];
    latlongCoords = Table[GeoMarker@latlongCoords[[i]], {i, Length@xyzCoords}];
    outtype = ChoiceDialog["Type of map?", {"2D" -> 1, "3D" -> 2}];
    Switch[outtype,
     1, GeoGraphics[latlongCoords, GeoRange -> "World", GeoProjection -> "Robinson"],
     2, Graphics3D[{PointSize@Large,
           Point@Table[Normalize@xyzCoords[[i]], {i, Length@xyzCoords}],
           Opacity@0.5, Sphere[]}]
    ]
 ]

These are the ITRF00 coordinates for Brazilia, Berlin and New Delhi. You can input them in one go, selecting the "All" alternative and paste:

{{4115144, -4555919, -1723314}, {3783638, 899994, 5038219}, {1239693, 5465361, 3035052}}

A number of typos and misunderstandings and missing semicolons, all of which cause problems.

Compare this, character by character with your original and track down why each change is there

xlist = {};
ylist = {};
zlist = {};
latlonlist = {};
(Label[startinput];
x = Input["What is the x coordinate?"];
y = Input["What is the y coordinate?"];
z = Input["What is the z coordinate?"];
AppendTo[xlist, x];
AppendTo[ylist, y];
AppendTo[zlist, z];
(Label[errorcontrol];
   again = InputString["Enter more coords? Y for yes, N for no"];
   If[again == "Y", Print["Okay!"]; Goto[startinput]];
   If[again != "N", Print["Sorry, this is an invalid input here!"];
   Goto[errorcontrol]]; If[again == "N", Print["Okay."]]));
list = Transpose[{xlist, ylist, zlist}];
qty = Length[list];
For[i = 1, i <= qty, i++,
   point = Part[list, i];
   AppendTo[latlonlist, GeoMarker[GeoPosition[point]]];
];
GeoGraphics[latlonlist, GeoRange -> "World", GeoProjection -> "Robinson"]
ListPointPlot3D[list, DataRange -> {{-1000000, 1000000}, {-1000000, 1000000}}]