Message Boards Message Boards

GROUPS:

[GIF] Rise Up ((29, 5)-torus knot)

Posted 5 years ago
6494 Views
|
3 Replies
|
9 Total Likes
|

(29,5)-torus knot

Rise Up

Continuing the torus knot theme (1, 2, 3). This is just a simple rotation of a $(29,5)$-torus knot. It's entirely three-dimensional, but because it's much simpler to parametrize torus knots on the Clifford torus in 4D, I am as usual parametrizing there and then stereographically projecting to 3D.

Here's the code:

Stereo3D[{x1_, y1_, x2_, y2_}] := {x1/(1 - y2), y1/(1 - y2), x2/(1 - y2)};

pqtorus[t_, ϕ_, p_, q_] := 1/Sqrt[2] {E^(p I (t + ϕ/p)), E^(q I t)};

With[{viewpoint = {0, 3, 0}, n = 450*29, p = 29, q = 5, 
  cols = RGBColor /@ {"#F21368", "#22C7A9", "#474655"}},
 Manipulate[
  Graphics3D[
   {Tube[Table[Stereo3D[Flatten[ReIm /@ pqtorus[t, -ϕ, p, -q]]], {t, 0., 2 Pi, 2 Pi/n}], .07]},
   PlotRange -> 2.7, ViewPoint -> viewpoint, ViewAngle -> Pi/9, 
   ViewVertical -> {0, 0, -1}, Boxed -> False, 
   Background -> cols[[-1]], ImageSize -> 540,
   Lighting -> {{"Point", cols[[1]], {3/4, 0, 0}}, {"Point",  cols[[2]], {-3/4, 0, 0}}, 
     {"Ambient", cols[[-1]], viewpoint}, {"Point", Darker[cols[[-1]], .87], viewpoint}}],
  {ϕ, 0, 2 Pi/q}]
 ]
3 Replies
Posted 3 years ago

Hi Clayton Shonkwiler

I am a graphic designer I designed new brand based on toru.

Can I use this gif just in my presentation?

This is my portfolio be.net/karram

Thanks. karram

POSTED BY: mohamed karram

Hi Karram,

All my animations are covered by a Creative Commons Attribution-NonCommercial-NoDerivatives license, which basically says you can use them for non-commercial purposes as long as you credit me.

Best,

Clay

enter image description here -- you have earned Featured Contributor Badge enter image description here Your exceptional post has been selected for our editorial column Staff Picks http://wolfr.am/StaffPicks and Your Profile is now distinguished by a Featured Contributor Badge and is displayed on the Featured Contributor Board. Thank you!

POSTED BY: Moderation Team
Reply to this discussion
Community posts can be styled and formatted using the Markdown syntax.
Reply Preview
Attachments
Remove
or Discard

Group Abstract Group Abstract