Message Boards

GROUPS:

Staff Picks Astronomy Data Science Mathematica Graphics and Visualization Import and Export Wolfram Language Geographic Information System

Jeff Bryant

Visualizing the Unified Geologic Map of the Moon from the USGS

Jeff Bryant, Wolfram|Alpha, LLC

Posted 11 months ago

2994 Views

3 Replies

13 Total Likes

Follow this post

On March 3, 2020, the United Stated Geological Survey (USGS) published a new data set that covers lunar geology. The data was built on an older 2013 data set, but includes data from the Lunar Reconnaissance Orbiter (LRO). The final data set is a large 214 MB ZIP file containing a SHP file and all of its support files, including labels. The data mainly covers geological ages for the Moon. The goal is to import this data and combine it with GeoGraphics functionality in the Wolfram Language.

EmbeddedService[{"YouTube","NbMxQtgy06Y"}]

In[]:=

Out[]=

Importing the Raw Data

This works best if you are running in desktop since you need to download the data file from the USGS first. Once the data file, available from the link above, is downloaded it can be placed in the same directory as the notebook and then the following can be evaluated.

SetDirectory[NotebookDirectory[]];

In[]:=

Its important to know what coordinate system is being used by the data set so that it can be properly translated for use in GeoGraphics later.

csi=Import["Unified_Geologic_Map_of_the_Moon_GIS_v2.zip","CoordinateSystemInformation"]

In[]:=

PROJCS{Moon2000_EquidistantCylindrical_clon0,GEOGCS{GCS_Moon_2000,DATUM{Moon_2000,SPHEROID{Moon_2000_IAU_IAG,1.7374×

,0.}},PRIMEM{Reference_Meridian,0.},UNIT{Degree,0.0174533}},PROJECTION{Equirectangular},PARAMETER{False_Easting,0.},PARAMETER{False_Northing,0.},PARAMETER{Central_Meridian,0.},PARAMETER{Standard_Parallel_1,0.},UNIT{Meter,1.}}

Out[]=

Now that we have the information above, we want to actually import the data.

shpdata=Import["Unified_Geologic_Map_of_the_Moon_GIS_v2.zip","Data"];

In[]:=

Extracting and Preparing Relevant Data

One of the things we need to know is how to label the various geometry elements. We can do this by accessing the “LabeledData”

shpdata[[1,All,1]]

In[]:=

{LayerName,Geometry,Labels,LabeledData}

Out[]=

labeleddata="LabeledData"/.shpdata[[1]];

In[]:=

labeleddata[[All,1]]

In[]:=

{FIRST_Unit,FIRST_Un_1,FIRST_Un_2,Shape_Leng,Shape_Area,AREA_GEO}

Out[]=

By examination, we want to use “FIRST_Un_1” as the labels since they are not abbreviated.

types="FIRST_Un_1"/.labeleddata;

In[]:=

Union[types]

In[]:=

{Copernican,Eratosthenian,Eratosthenian-Imbrian,Imbrian,Imbrian-Nectarian,Nectarian,Pre-Nectarian}

Out[]=

For each label, we want to assign a specific set of styles, including color. The following colors were manually specified based on officially recognized color for the Lunar Geologic Timescale. Boundary regions such as ”Imbrian-Nectarian” are colored based on a 50% blend of the relevant colors.

colorrules="Pre-Nectarian"GeoStylingEdgeForm

,RGBColor@@{0.8196078431372549`,0.30196078431372547`,0.3764705882352941`},Opacity[0.4`],"Nectarian"GeoStylingEdgeForm

,RGBColor@@{0.8941176470588235`,0.3254901960784314`,0.07058823529411765`},Opacity[0.4`],"Imbrian-Nectarian"GeoStylingEdgeForm

,Blend[{RGBColor@@{0.`,0.4784313725490196`,0.807843137254902`},RGBColor@@{0.8941176470588235`,0.3254901960784314`,0.07058823529411765`}},.5],Opacity[0.4`],"Imbrian"GeoStylingEdgeForm

,RGBColor@@{0.`,0.4784313725490196`,0.807843137254902`},Opacity[0.4`],"Eratosthenian-Imbrian"GeoStylingEdgeForm

,Blend[{RGBColor@@{0.23529411764705882`,0.8352941176470589`,0.7254901960784313`},RGBColor@@{0.`,0.4784313725490196`,0.807843137254902`}},.5],Opacity[0.4`],"Eratosthenian"GeoStylingEdgeForm

,RGBColor@@{0.23529411764705882`,0.8352941176470589`,0.7254901960784313`},Opacity[0.4`],"Copernican"GeoStylingEdgeForm

,RGBColor@@{0.4980392156862745`,0.4980392156862745`,0.4980392156862745`},Opacity[0.4`];

In[]:=

legend=SwatchLegend[colorrules[[All,2,2]],colorrules[[All,1]],LegendLayout"Row"]

In[]:=

Pre-Nectarian

Nectarian

Imbrian-Nectarian

Imbrian

Eratosthenian-Imbrian

Eratosthenian

Copernican

Out[]=

Now that we’ve created a legend for the data, we now need to extract the geometry data itself.

polys="Geometry"/.shpdata[[1]];

In[]:=

The data contains a number of Polygon and FilledCurve primitives that need to be converted into useful coordinates system in order to be plotted in GeoGraphics. GeoGridPosition is used to convert the coordinate system from the reference model specified near the top of this document. FilledCurves are converted to Polygons.

convertedpolys=polys/.{Polygon[data_]Polygon[GeoPosition@GeoGridPosition[data,{"Equirectangular","ReferenceModel"1.7374`*^6},Entity["PlanetaryMoon","Moon"]]],FilledCurve[data_](data/.Line[data1_]Polygon[GeoPosition@GeoGridPosition[data1,{"Equirectangular","ReferenceModel"1.7374`*^6},Entity["PlanetaryMoon","Moon"]]])};

In[]:=

We can combine the polygon data with the color and style information as follows.

data=Reverse[Transpose[{types/.colorrules,convertedpolys}]];

In[]:=

Creating Maps

Now that the data had been prepared, we are ready to start visualizing it. The primary tool used is GeoGraphics. As a first step, we view the entire global data set using an equirectangular projection.

LegendedGeoGraphics{data},GeoModel

Moon	PLANETARY MOON

,GeoProjection"Equirectangular",GeoRangeAll,ImageSize600,Placed[legend,Below]

In[]:=

Out[]=

For a more natural appearance, an orthographic projection can be used to view the near-side of the Moon (left) and the far-side of the Moon (right). The far-side exposes far more older (pre-Nectarian and Nectarian) geological units than the near-side does.

LegendedGraphicsGridGeoGraphics{data},GeoModel

Moon	PLANETARY MOON

,GeoRangeAll,GeoProjection{"Orthographic","Centering"#},GeoZoomLevel2&/@{GeoPosition[{0,0}],GeoPosition[{0,180}]},ImageSize600,Placed[legend,Below]

In[]:=

Out[]=

We can also zoom into a particular region to see finer detail.

LegendedGeoGraphics{data},GeoModel

Moon	PLANETARY MOON

,GeoCenter

Albategnius crater

SOLAR SYSTEM FEATURE

,GeoRangeQuantity[500,"Miles"],GeoProjection"Mercator",ImageSize600,Placed[legend,Below]

In[]:=

Out[]=

Globe

With an equirectangular projection, we can construct a texture map that can be placed onto a ParametricPlot3D representation of a sphere.

texture=ImageReflect[Image[GeoGraphics[{data},GeoModelEntity["PlanetaryMoon","Moon"],GeoProjection"Equirectangular",GeoRangeAll,ImageSize1920]],Top];

In[]:=

gr=ParametricPlot3D[{Cos[ϕ]*Sin[θ],Sin[ϕ]*Sin[θ],Cos[θ]},{ϕ,0,2π},{θ,0,π},PlotStyleTexture[texture],BoxedFalse,AxesNone,BackgroundBlack,Lighting"Neutral",ImageSize{1920,1080},MeshStyleGray,SphericalRegionTrue,ViewAnglePi/10];

In[]:=

Show[gr,ImageSize600]

In[]:=

Out[]=

Animation

Now that we have a textured globe, its a fairly easy extension to animate the 3D object by simply moving the ViewPoint around the equator of the sphere. Here, we generate a set of 600 frames where the ViewPoint is slowly rotated around the sphere.

frames=Table[Show[gr,ViewPoint{-3Cos[t],-3Sin[t],0},Lighting{{"Ambient",GrayLevel[.3]},{"Directional",White,ImageScaled[{0,0,1}]}}],{t,0,2Pi-2Pi/600,2Pi/600}];

In[]:=

To create the animation, there are a couple of ways to proceed. One way is to export the frames to a directory and then combine those frames later, something like the following.

Do[Export["frames\\Frame"<>ToString[PaddedForm[t,3,NumberPadding"0",NumberSigns{"",""}]]<>".png",frames[[t]],"PNG"],{t,1,Length[frames],1}]

Another option, available in version 12.1, is to export the frames directly to an MPEG file.

Export["moongeo2.mp4",frames]

The resulting movie can be seen below.

EmbeddedService[{"YouTube","NbMxQtgy06Y"}]

In[]:=

Out[]=

POSTED BY: Jeff Bryant

Answer

3 Replies

Sort By:

Moderation Team

Moderation Team, WOLFRAM

Posted 11 months ago

-- you have earned *Featured Contributor Badge* Your exceptional post has been selected for our editorial column *Staff Picks* http://wolfr.am/StaffPicks and Your Profile is now distinguished by a *Featured Contributor Badge* and is displayed on the Featured Contributor Board. Thank you!

POSTED BY: Moderation Team

Answer

Jeff Bryant

Jeff Bryant, Wolfram|Alpha, LLC

Posted 11 months ago

For what its worth, the USGS website keeps going down and coming back up: https://astrogeology.usgs.gov/search/map/Moon/Geology/Unified_Geologic_Map_of_the_Moon_GIS So, if it doesn't come up for you, try again later. It was working fine when I wrote this content, but did go down once while I was writing it. Then it came back, but is down again as I write this comment.

POSTED BY: Jeff Bryant

Answer

Moderation Team

Moderation Team, WOLFRAM

Posted 6 months ago

Congratulations! This post was featured in the Wolfram Blog *Wolfram Community Takes on Current Events: COVID-19 Data, Green Spaces, Homeschool Puzzles and More*. We are looking forward to your future contributions.

POSTED BY: Moderation Team

Answer

Reply to this discussion

Reply Preview

Attachments

Remove Add a file to this post

Follow this discussion

or Discard

Group Abstract

Feedback