I see your point. On the other hand the problem that you encountered is mostly because the time series is to equidistantly sampled, because there are no data points on the weekends. So getting the data is rather straight forward, but the sampling needs to be taken into consideration. I think that that's more of a data analysis problem, rather than a curated data problem.

To fix the sampling issue I separated the "data from the dates" , then did the forecast bit, and then added the dates in again. You could use several alternative strategies, e.g. use the Function TimeSeriesResample you can also fix the problem; and I only have to work with TimeSeries data. The idea is like this:

dkfresamp = TimeSeriesResample[dkf];

I then fit a model (which in this case is not a good one!):

model = EstimatedProcess[dkfresamp, ARIMAProcess[{a, b, c}, d, {e, f}, g]]

I then forecast

forecast2 = TimeSeriesForecast[model, dkfresamp, {20}, Method -> "Kalman"]

and plot:

DateListPlot[{dkfresamp, forecast2}]

Of course the fit is quite unsatisfactory in this case, but the program runs through without any error messages and I do not need to split the dates from the values.

Best wishes,

M.

PS: If you want the time series in a standard date, value format you can use:

dkfresamp2 = {DateList[#[[1]]], #[[2]]} & /@ dkfresamp;

Hi,

I am not sure whether that question is still related to the MissingData issue. There are some problems in that code, for example that there is a change between scalar data and data with dates - as needed for the DateListPlot.

The following might work:

(*Download the data*)

dkf = FinancialData["GE", {{2012, 5, 1}, {2012, 9, 30}}];

(*Make data scalar and fit time series*)

data = dkf[[All, 2]];
epoc = EstimatedProcess[data, ARIMAProcess[{a, b, c}, d, {e, f}, g]];

(*Forecast based on the model*)

forecasr = TimeSeriesForecast[epoc, data, {20}];

(*Join data and forecast*)

datapred = Join[data, Flatten[forecasr["Paths"], 1][[All, 2]]];

(*Generate dates for the DateListPlot; the BusinessDay option requires MMA10.0.2*)

dates = DateRange[dkf[[1, 1]], DayPlus[dkf[[-1, 1]], 31], "BusinessDay"];

(*Then Plot*)

DateListPlot[{Transpose[{dates, datapred}][[1 ;; Length[dkf]]], Transpose[{dates, datapred}][[Length[dkf] ;;]]}, Joined -> True, Filling -> Axis, PlotLabel -> "GE", ImageSize -> 350]

The result looks like this:

There is no problem with MissingData, and I am not sure whether this relates to the original post.

Cheers,

M.

In my stumbling around to see what I was doing wrong, I changed the code from [[All,2]] to [[All]].

Thank you.

Hi,

I cannot reproduce that. If I download the data you say, I do not get any missing data at all. If however, I download this:

WeatherData["EEKA",  "WindSpeed", {{2004, 7, 12}, {2004, 7, 30}}] // Normal

I do get missing data. In that case your function:

Select[WeatherData["EEKA", "WindSpeed", {{2004, 5, 1}, {2004, 9, 30}}] // Normal, FreeQ[#, Missing] &]

appears to work as expected. If you want you can export the time series that you get and attach it to a post in this thread. I'll try with that then.

Cheers,

M.