Message Boards Message Boards

Get Ready for the Perseid Meteor Shower Tonight

Meteor showers are an annual occurrence. Each meteor shower happens at about the same time every year. One of the better meteor showers to catch, at least in the northern hemisphere, is the Perseid meteor shower.

In[1]:= Entity["MeteorShower", "Perseids"]["PeakDate"]

Out[1]= DateObject[{2016, 8, 12}]

Meteor showers are usually the result of Earth moving through the dusty debris trail of a periodic comet. As comets orbit the Sun, they leave behind a dusty cloud in their wake. Some comet orbits pass near the orbit of Earth and so the Earth intercepts some of this dirt and gravel. In the case of the Perseid meteor shower, the parent object is Comet Swift-Tuttle.

In[2]:= Entity["MeteorShower", "Perseids"]["ParentObject"]

Out[2]= Entity["Comet", "Comet109PSwiftTuttle"]

The orbit of this comet can be visualized using the following WL code.

With[{date = DateObject[{2016, 8, 11}]}, 
 Graphics3D[{RGBColor[1, .7, 
    0], {Lighting -> {{"Ambient", GrayLevel[.3]}, {"Directional", 
       White, ImageScaled[{0, 0, 1}]}}, Sphere[{0, 0, 0}, .1]}, 
   PointSize[.02], {{Orange, 
       Lighting -> {{"Ambient", GrayLevel[.3]}, {"Directional", White,
           ImageScaled[{0, 0, 1}]}}, #[[1]]}, 
      Point[QuantityMagnitude[#[[2]]]]} &@
    EntityValue[
     Entity["Comet", "Comet109PSwiftTuttle"], {"OrbitPath", 
      EntityProperty["Comet", "HelioCoordinates", {"Date" -> date}]}],
    Blue, EntityValue[EntityClass["Planet", All], "OrbitPath"]}, 
  PlotRange -> 45, ViewAngle -> Pi/20, Boxed -> False, 
  ImageSize -> 400]]

orbit of Comet Swift-Tuttle

If we zoom into the inner solar system, we can represent the comet's orbit as a tube and watch as Earth passes through the comet's orbit path as we approach August 11.

frames = Table[
  With[{date = DateObject[{2016, 7, 11 + t}]}, 
   Column[{DateObject[date[[1]], 
      DateFormat -> {"MonthNameShort", " ", "DayShort"}], 
     Graphics3D[{RGBColor[1, .7, 
        0], {Lighting -> {{"Ambient", GrayLevel[.3]}, {"Directional", 
           White, ImageScaled[{0, 0, 1}]}}, Sphere[{0, 0, 0}, .1]}, 
       PointSize[.02], {{Orange, 
           Lighting -> {{"Ambient", GrayLevel[.3]}, {"Directional", 
              White, ImageScaled[{0, 0, 1}]}}, #[[1]] /. 
            Line -> Tube}, Point[QuantityMagnitude[#[[2]]]]} &@
        EntityValue[
         Entity["Comet", "Comet109PSwiftTuttle"], {"OrbitPath", 
          EntityProperty["Comet", 
           "HelioCoordinates", {"Date" -> date}]}], 
       Blue, {#[[1]], {Text[#[[1]], 
              QuantityMagnitude[#[[2]]], {-1.5, 0}] & /@ 
            Transpose[{#[[3]], #[[2]]}], 
           Point[QuantityMagnitude[#[[2]]]]}} &@
        Transpose[
         EntityValue[{Entity["Planet", "Earth"], 
           Entity["Planet", "Venus"], Entity["Planet", "Mercury"], 
           Entity["Planet", "Mars"]}, {"OrbitPath", 
           EntityProperty["Planet", 
            "HelioCoordinates", {"Date" -> date}], "Name"}]]}, 
      PlotRange -> 4, ViewAngle -> Pi/20, Boxed -> False, 
      ImageSize -> 400]}, Center]],
  {t, 0, 60, .5}];

Animation of Earth moving through the orbital path of comet Swift-Tuttle

Depending on the weather in your location, you should try going out over the next couple of days, especially tonight, and look for any "shooting stars" that are a result of the dusty debris of a comet burning up in our atmosphere. The best time is anytime after midnight and before dawn. Meteors can appear anywhere in the sky and will appear to radiate from a point in the northeast, in the constellation Perseus, where the meteor shower gets its name. You don't need binoculars or a telescope, just a blanket and your eyes.

POSTED BY: Jeffrey Bryant
5 Replies
Posted 8 years ago

I saw 17 of them in half an hour, 5 bright ones

POSTED BY: Olaf Baeyens

enter image description here - another post of yours has been selected for the Staff Picks group, congratulations !

We are happy to see you at the top of the "Featured Contributor" board. Thank you for your wonderful contributions, and please keep them coming!

POSTED BY: Moderation Team

Thanks for sharing Jeff! Quite amazing that all this info is available!

POSTED BY: Sander Huisman

Thanks for the informative post, Jeff!!

I'm always amazed when I see 3-D visualizations of the solar system. Everyday occurrences just make so much more sense.....

POSTED BY: Rob Morris

BTW, I should add that this meteor shower typically produces about 100 meteors per hour:

In[5]:= Entity["MeteorShower", "Perseids"]["PeakZHR"]

Out[5]= Quantity[1.0*10^2, 1/("Hours")]

Although some predictions are claiming that this years shower could be double that. Predicting meteor shower performance is more art than science and can vary from one location to the next given that there can be narrow bursts that favor one location and not another.

POSTED BY: Jeffrey Bryant
Reply to this discussion
Community posts can be styled and formatted using the Markdown syntax.
Reply Preview
Attachments
Remove
or Discard

Group Abstract Group Abstract