Here is another way to represent this.

domain = Range[-5, 10, 0.1];
sols1 = Table[5 Surd[ x, 3]^2 - Surd[x, 3]^5, {x, -5, 10, 0.1}];
sols2 = Table[5 x^(2/3) - x^(5/3), {x, -5, 10, 0.1}];
sols3 = Conjugate /@ sols2;
ListPointPlot3D[{Flatten /@ 
  Transpose[{domain, {Re[#], Im[#]} & /@ sols2}], 
  Flatten /@ Transpose[{domain, {Re[#], Im[#]} & /@ sols3}], 
  Flatten /@ Transpose[{domain, {Re[#], Im[#]} & /@ sols1}]}, 
 AspectRatio -> 1, AxesLabel -> {"x-Axis", "real", "imaginary"}, 
 LabelStyle -> Directive[Bold, Medium]]

The domain-variable just is input to our function. sols1 computes the real-values of the root (green curve in the picture). sols2 and sols3 are the principal (complex) solutions to the roots together with the conjugate complex solutions. Because the roots of negative numbers are not unique in general, we can get more than one "solution". If other pieces of software assume that we want only the real roots, they do not have issues with this, but do make some potentially critical assumptions that we might not want to make.

Cheers,

M.

PS: The figure is actually not easy to read this way. It shows how much better it is to have Mathematic than a static document. If you take compute it and rotate it, it becomes much clearer.

PPS: If you dislike the awkward way of plotting the lists of points you can, of course, also use ParametricPlot3D

Show[ParametricPlot3D[{x, Re[5 x^(2/3) - x^(5/3)], 
   Im[5 x^(2/3) - x^(5/3)]}, {x, -5, 10}, AspectRatio -> 1, 
  PlotStyle -> Red, PlotRange -> {{-5, 10}, {-20, 20}, {-20, 20}}], 
 ParametricPlot3D[{x, 
   Re[5 x^(2/3) - x^(5/3)], -Im[5 x^(2/3) - x^(5/3)]}, {x, -5, 10}, 
  AspectRatio -> 1, PlotStyle -> Red], 
 ParametricPlot3D[{x, Re[5 Surd[x, 3]^2 - Surd[x, 3]^5], 
   Im[5 Surd[ x, 3]^2 - Surd[x, 3]^5]}, {x, -5, 10}]]

The blue line is the "real" solution and the other two correspond to "complex and conjugate complex solutions".

Marco, that is most enlightening!

In[4]:= Reduce[5 Surd[x, 3]^2 - Surd[x, 3]^5 > 0]

Out[4]= x < 0 || 0 < x < 5

Hi Rosa,

If you mean the domain such that the last expression is positive and real, here is a Mathematica solution:

In[1]:= Reduce[5 x^(2/3) - x^(5/3) > 0]

Out[1]= 0 < x < 5

In[2]:= Plot[5 x^(2/3) - x^(5/3), {x, -5, 10}]

The Reduce expression also works in Alpha.

Kind regards,

David

Dear Rosa,

well, I do not know which other mathematical software you use. I suppose that Mathematica is just more general and can give more solutions. For example, when you want to evaluate something like

5 x^(2/3) - x^(5/3)

you need to evaluate the individual terms. The issue arises because you are taking uneven roots of negative numbers. So what is the third root of -1? We are asking for the number which if multiplied three times by itself gives -1, right? Now, one solution is clearly -1. It is real and the solution that you expect. But it is not the only solution. It turns out that 0.5000000000000001+ 0.8660254037844386 I and 0.5000000000000001-0.8660254037844386 I are also valid solutions (in the complex numbers). If the -1^(1/3) does not have a unique solution then your function is not actually a function. So the question is what exactly do you mean. I think it is Surd, i.e. the real root. Mathematica is not prejudiced about reals or complex numbers.

So I suppose that it is just better than the other software that you are using. When you say

I'm confused, in other mathematical software, I put me the correct function and graphic appears and the graph appears mathematicas me only positive real

then it is not quite true that the other software gives you the "correct" solution. Strictly speaking, it gives you a partial solution that happens to be what you expect. It is in the definition of the third root function. Surd[x,3] gives you the real solution to the question what number do I have to multiply three time with itself to get x. Power gives you the principal solution to the same question, which for negative x can be complex.

Think of it as follows. The square root is defined as the positive number that when squared gives some other number. So the square root of 4 gives 2. It (partially) solves the equation

x^2==4

In the sense that it looks for the positive x that fulfils that equation. In principle there is another solution to the equation of course, which is -2. I have to choose one of the two solutions because I want Sqrt to be a function, i.e. something with a single output value. Things become more complicated when have an odd root of a negative number. There is one (negative) real solution, but there are in general more complex solutions. Also now, any function that helps us find a solution needs a single value. The real solution is given by Surd. If you use ^ or equivalently Power you do not calculate the real solution but the principal solution. As that happens to be complex, that restricts your "real" domain.

I admit that I might not make myself quite clear here.

Cheers,

M.

I do not ask for the command. But other mathematical software in the domain of this function is all real and wolfram alpha is positive real

Dear Rosa,

I am not really sure what your question is. Your two posts are not identical and the question seems to be in complete somehow.

In Mathematica / the Wolfram Language you would type:

FunctionDomain[5 x^(2/3) - x^(5/3), x]

Something similar works in Wolfram|Alpha, see here. I am not sure whether that helps.

Cheers,

M.