Message Boards Message Boards

5
|
10913 Views
|
4 Replies
|
17 Total Likes
View groups...
Share
Share this post:

Finding a function for the skiing angle from acceleration

Posted 11 years ago
I was skiing the other day when I had thought about the physics of skiing.

I figured, if a block that can measure acceleration or velocity was sent down a hill, given the coefficient of friction, one can calculate the general shape of the slide.

So, through my limited physics skills, I derived 
Net force in the horizontal direction = Force applied by gravity - Force of friction
or
Net force in the horizontal direction = (Force of Gravity)(Sin of slope's angle) - (Coefficient of friction)(Force of Gravity)(Cos of slope's angle)
which simplifies to
a = g(Sin[o]-u*Cos[o])
*a=accleration, g=gravity, u=coefficient of friction, o=angle.

At this point, I realized that solving for the angle will take complicated trigonometry. Therefore, I tried the Solve function,
 Solve[a == g (Sin[o] - u*Cos[o]), o]
 
 {{o -> ConditionalExpression[
     ArcTan[(-a g u - Sqrt[-a^2 g^2 + g^4 + g^4 u^2])/(
       g^2 + g^2 u^2), (
       a - (a g^2 u^2)/(g^2 + g^2 u^2) - (
        g u Sqrt[-a^2 g^2 + g^4 + g^4 u^2])/(g^2 + g^2 u^2))/g] +
      2 \[Pi] C[1], C[1] \[Element] Integers]}, {o ->
    ConditionalExpression[
    ArcTan[(-a g u + Sqrt[-a^2 g^2 + g^4 + g^4 u^2])/(
      g^2 + g^2 u^2), (
      a - (a g^2 u^2)/(g^2 + g^2 u^2) + (
       g u Sqrt[-a^2 g^2 + g^4 + g^4 u^2])/(g^2 + g^2 u^2))/g] +
     2 \[Pi] C[1], C[1] \[Element] Integers]}}
And I was stumped.

Is this the complicated answer I was supposed to get? Or was there something I typed in wrong and the actual equation isn't as complex?

Can anybody help me?

Thank you,

I apologize for the lengthiness of the post. If some part of it is unclear, I apologize.
POSTED BY: Seokin Yeh
4 Replies
I just wanted to say that I have enjoyed reading through this discussion very much. Great question and great answers.

Seokin I know that you have attended Mathematica Summer Camp 2013 and recently published a Demonstration: Playing Blackjack - which I indulge myself in testing ;-)

If you have more programming ideas - please do share!
POSTED BY: Vitaliy Kaurov
Thank you to both Ahmed and Luca.

@Ahmed
I was thinking that one of the issues were that I did not give a range for the angle (so the angle can be 30, 390, 750, and so on), but I could not, for the life of me, figure out how to fix the problem nor find any other issues.
Thank you so much.

@Luca
That was one of those beautiful mathematics. Where the mathematical properties are entwined in a complex way to create something relatively simple. I loved it.

I think that mathematica is a great program. I use it frequently to figure out mathematics beyond my knowledge, and I think that is a great aspect of mathematica, because once mathematica solves the equation, I can start to understand the process.

Thank you again for the help.
POSTED BY: Seokin Yeh
Posted 11 years ago
Saying that Mathematica is a great software, I think it is sometimes rather awkward when it is used to deal with goniometric equations and functions, even in simple cases.
Anyway the proposed problem can be solved analitically with some goniometric transformation:


Here's a Manipulate with the two (identical) plots of alfa as a function of a and the possibility to change the parameters mu and g. The physical domain is the part of the curve under the line alfa=90°
 Manipulate[
  Plot[{180/\[Pi] (ArcSin[a/(g Sqrt[1 + \[Mu]^2])] + ArcTan[\[Mu]]) If[
      f1, 1, 0],
    180/\[Pi] 2 ArcTan[(g - Sqrt[-a^2 + g^2 + g^2 \[Mu]^2])/(
      a - g \[Mu])] If[f2, 1, 0], 90}, {a, 0, 11},
   PlotRange -> {0, 210}], {{g, 9.8}, 0, 12,
   Appearance -> "Labeled"}, {{\[Mu], 0.2}, 0, 4,
   Appearance -> "Labeled"}, {{f1, True, "Method 1"}, {True,
    False}}, {{f2, True, "Method 2"}, {True, False}}]
POSTED BY: Luca M
As I understood, you are talking about a Mass on an inclined rough surface.



I have used the numerical solve function to get a somhow simplistic answer. What is more important, however, is to add some simplification to your expression, as follows:
  • Set C[1] to zero. (the infinite term of 2 pi C[1] is due to the presence of the trignometric functions.)
  • Mu (the coefficient of friction) is Real and greater than zero.
  • alpha is Real and has a value between 0 degree (no inclination) and 90 degrees (the surface is vertical). 
FullSimplify[
  NSolve[a ==
     g (Sin[\[Alpha] \[Degree]] - \[Mu] Cos[\[Alpha] \[Degree]]), \
\[Alpha]] /.
   C[1] -> 0, {{\[Mu], \[Alpha], a} \[Element] Reals, \[Mu] > 0,
   90 >= \[Alpha] >= 0}] // Rationalize

the result is:



Taking the second answer, which is more physically reasonable:
57.2958 ArcTan[(-a g \[Mu] + Sqrt[-a^2 g^2 + g^4 (1 + \[Mu]^2)])/
  g^2, (a g + \[Mu] Sqrt[-a^2 g^2 + g^4 (1 + \[Mu]^2)])/g^2]

Checking the angle for different accelerations:
Table[57.29577951308232` ArcTan[(-a g \[Mu] +
     Sqrt[-a^2 g^2 + g^4 (1 + \[Mu]^2)])/g^2, (
    a g + \[Mu] Sqrt[-a^2 g^2 + g^4 (1 + \[Mu]^2)])/g^2] /. {\[Mu] ->
    0.2, g -> 9.81}, {a, {0, 1, 2, 3, 6, 7, 9.81}}]

the result is:
{11.3099, 17.0466, 22.8419, 28.7598, 48.1615, 55.7129, 90.}

Which I believe is quite good. At zero acceleration, the angle is 11.3099 (the mass is not sliding due the roughness of the surface). And when the acceleration is equal to gravity (the mass is freely falling), the angle is 90 degrees.

I hope this helps @Seokin in any way.

Regards...
POSTED BY: Ahmed Mogahed
Reply to this discussion
Community posts can be styled and formatted using the Markdown syntax.
Reply Preview
Attachments
Remove
or Discard

Group Abstract Group Abstract