I just came across a puzzle on phys.org, which apparently went viral on Twitter. Ed Southall posted a question regarding a problem about the area of a triangle. We are asked what fraction of the area the pink triangle occupies:

It is quite easy to find the answer. What is more interesting is to find as many ways as possible for that. On MentalFloss they describe some approaches to solve the puzzle. The main idea of the "classical solutions" presented on that website are based on the similarity of triangles. I was wondering what computational thinking and the Wolfram Language could do for us...

Setting the problem up

It is necessary to "interpret the sketch". For example, we need to recognise that we can choose the base to be of length one, and that the other two sides have slope 2 and -1. With that we can define the region like so:

reg = ImplicitRegion[2 x >= y && y <= 1 - x && 0 <= x <= 1 && 0 <= y <= 1, {x, y}];

I generated the plot above with this function:

RegionPlot[reg, PlotRange -> {{0, 1}, {0, 1}}, PlotStyle -> RGBColor[1, .1, 1], FrameTicks -> False]

Stephen Wolfram often says that the Wolfram Language is very useful also to state problems (read his blog posts on AI and on communicating with aliens). This becomes quite clear here. The definition of the ImplicitRegion makes the problem very clear; in fact much more precise than the image alone!

Solution 1

The easiest solution is now to ask Mathematica directly for the answer:

Area[reg]

which gives 1/3 as expected.

Solution 2

We can also use a Monte Carlo approach and generate points in the unit square and see how many of them are in the "pink region":

M = 1000000; N[Length[Select[RandomPoint[Rectangle[{0, 0}, {1, 1}], M], 2 #[[1]] >= #[[2]] && #[[2]] <= 1 - #[[1]] &]]/M]

which obviously gives slightly different results every time you run it. I got 0.333633 which is quite close to 1/3.

Solution 3

The problem with the previous solution is that it is numerical and only gives an approximate value. The Wolfram Language also allows us to use the distributions to effectively run a Monte Carlo simulation on an "infinite number of points".

dist = UniformDistribution[{{0, 1}, {0, 1}}];
Probability[2 x >= y \[And] y <= 1 - x, {x, y} \[Distributed] dist]

which results in 1/3, so the precise result.

Solution 4

If we recognise that in the definition of the implicit region defines the region by using the equations of two straight lines

y==2 x && y == 1 - x 

We can then calculate where they intersect, i.e. the tip of the triangle:

sols = Solve[y == 2 x && y == 1 - x, {x, y}]

This gives

{{x -> 1/3, y -> 2/3}}

Where y is the height of the triangle. So then the area of the pink triangle is

area=1/2 (x*y) + 1/2 ((1 - x)*y) /. sols[[1]]

This come uses the hight line to calculate the areas of the resulting "left and right triangle". It is easier of course because we know that the length of the base of the triangle is 1 and the height is y so that we can write:

area = y/2

(Just simplify the previous equation to get to this result!)

As y is 2/3 we obtain 1/3 for the area of the pink triangle again.

Solution 5

This one is going to be nice. We first import the image from the phys.org website:

img = Import["https://3c1703fe8d.site.internapcdn.net/newman/gfx/news/2018/5ae713bf2d29a.jpg"];

You will notice that around the black square there is a slim white border, which can be removed using ImageCrop. There are three colours in the remaining plot: white, pink and black. We can ignore the black points (as they are only lines, i.e. one dimensional). The two dominating colours will be white and pink. So lets take all pixels and find three clusters of the values, corresponding to white, pink and black:

clusters = FindClusters[Flatten[ImageData[ImageCrop[img]], 1], 3];

We now need to count how many points/pixels we have in any cluster. Then we will sort the sizes, and ignore the smallest one (i.e. black). Then we compute the ratio of pink points to all points:

N[#[[2]]/Total[#[[{2, 3}]]]] &@Sort[Length /@ clusters]

which gives 0.333709, so a very good approximate value.

Conclusion

You will notice that some of the solutions are distinctly different from the analytical and geometrical approaches presented on the mental floss website. I would classify the approaches I describe here as rather "computational" approaches. I challenge you to find further computational approaches and see what we can contribute to the discussion on twitter.